Отладка приложений, обработка ошибок

Public Function IsGoodNum(var_Inp) As Boolean
'Функция возвращает True, если введенное
'число подходит, иначе - False
    If IsNumeric(var_Inp) = True _
        And Val(var_Inp) > 0 _
        And Val(var_Inp) < 255 _
    Then
        IsGoodNum = True
    Else
        IsGoodNum = False
    End If
End Function

Public Function IsMore100(var_Inp) As Boolean
'Функция возвращает True, если введенное число
'более 100
    If Val(var_Inp) > 100 Then
        IsMore100 = True
    Else
        IsMore100 = False
    End If
End Function

Public Function NotNumber(var_Inp) As String
'Определяет, что именно ввел пользователь
'вместо ожидаемого числа и возвращает
'строку для вывода сообщения об ошибке
    'Если не выполнится ни одно из условий
    'программа выдаст общее сообщение об
    'ошибке ввода данных
    NotNumber = "Ошибка ввода данных"
    'Если ей удастся определить тип ошибки
    'будет выведено более точное сообщение
    If var_Inp = "" Then
        NotNumber = "Вы забыли ввести возраст"
    End If
    If Val(var_Inp) < 0 Then
        NotNumber = "Вы ввели отрицательное число"
    End If
    If IsNumeric(var_Inp) = False Then
        NotNumber = "Вы ввели не число"
    End If
    If Val(var_Inp) > 255 Then
        NotNumber = "Вы ввели слишком большое число"
    End If
End Function

Private Sub cmd_AgeInput_Click()
    'Переменная для ввода пользователм
    Dim str_Inp
    'Сюда запишем возраст после проверки
    Dim num_Age As Byte
    'А здесь будем хранить ответ пользователя на
    'Вопрос о том, уверен ли он в том, что ему
    'Больше 100 лет
    Dim IsYouMore100 As Variant
    'В этой переменной будем хранить количество
    'Неправильных попыток ввода
    'Если оно превысит 3 - выходим из программы
    Dim num_InpTry As Byte
    'Эта переменная нужна для того, чтобы
    'определить, окончен ли опрос пользователя
    Dim bool_Flag As Boolean
    bool_Flag = False
    'Этот цикл будет длиться до тех пор,
    'пока пользователь не введет верное значение
    'или пока не совершит максимальное число
    'попыток
    Do
    str_Inp = InputBox("Введите ваш возраст")
        If num_InpTry > 3 Then
            MsgBox "Вы совершили более 3 ошибок"
            Exit Sub
        End If
        num_InpTry = num_InpTry + 1
        'Если введенное число подходит
        If IsGoodNum(str_Inp) = True Then
            'Проверяем - не больше ли оно 100
            If IsMore100(str_Inp) = False Then
            'Если не больше - просто устанавливаем
            'флаг выхода в True
            'и записываем возраст в переменную num_Age
                bool_Flag = True
                num_Age = CByte(str_Inp)
            Else
            'Если возраст больше 100 - переспросим
                IsYouMore100 = _
                MsgBox("Вам точно больше 100?", vbYesNo)
                'Если пользователь не ошибся,
                'Установим флаг выхода
                'и запишем возраст в num_Age
                If IsYouMore100 = vbYes Then
                    bool_Flag = True
                    num_Age = CByte(str_Inp)
                End If
           End If
        Else
        'Если пользователь изначально ввел
        'неподходяще число,
        'сгенерируем с помощью функции NotNumber
        'сообщение об ошибке и выведем его
            MsgBox (NotNumber(str_Inp))
        End If
    Loop Until bool_Flag = True
    MsgBox ("Ваш возраст: " + Str(num_Age))
End Sub

Private Sub cmd_InpAge_Easy_Click()
    Dim str_Inp
    Dim num_Age As Byte
    'Цикл продолжается до тех пор,
    'пока введенное значение не станет
    'числом, находящимся в диапазоне от
    '0 (не включая 0) до 100
    Do
        str_Inp = _
        InputBox("Введите ваш возраст")
    Loop Until _
    IsNumeric(str_Inp) = True _
    And Val(str_Inp) <= 100 _
    And Val(str_Inp) > 0
    'Конвертируем введенное число в
    'тип данных Byte
    num_Age = CByte(Val(str_Inp))
    MsgBox ("Ваш возраст: " + Str(num_Age))
End Sub