Структура приложений, использующих OpenGL

Цель лекции: Создать базовые приложения с использованием OpenGL на C# и на Object Pascal (Delphi).

Примеры

Пример № 3.1 Базовые приложения на C# (WinForms) и Object Pascal (Delphi), использующие библиотеку OpenGL.

В состав приложения, формирующего изображениe с помощью OpenGL, должно входить несколько программных блоков:

Инициализация OpenGL в библиотеке OpenTK

Инициализацию OpenGL в библиотеке OpenTK выполняет графический компонент GLControl, который размещается на одной из форм приложения. Вывод изображения, формируемого библиотекой OpenGL, выпоняется в области компонента GLControl. По умолчанию библиотека OpenTK инициализирует использование палитры RGBA, двойной буфер, устанавливает размер буфера глубины равным 16 бит.

Дополнительные настройки библиотеки OpenGL необходимо выполнять в обработчике события Load формы. В конструкторе формы этого делать не следует, так как еще не создан контекст изображения для компонента GLControl.

В следующем разделе рассмотрена инициализация библиотеки OpenGL в приложении на Object Pascal (Delphi). Аналогичную процедуру инициализации выполняет и библиотека OpenTK, чтобы в этом убедиться, достаточно заглянуть в исходный код этой библиотеки.

Инициализация библиотеки OpenGL в приложениях на Object Pascal (Delphi)

Перед началом использования команд OpenGL необходимо выполнить инициализацию библиотеки OpenGL. Основной задачей данного этапа является определение основных параметров работы библиотеки OpenGL, которые в дальнейшем не могут быть изменены без завершения работы с библиотекой OpenGL и её повторной инициализации. На этом этапе выполняется определение доступных возможностей аппаратуры для вывода изображения. Хотя библиотека OpenGL является кросплатформенной, но инициализация является специфичной для каждой платформы, поэтому на этом этапе используются функции операционной системы Windows. Инициализация библиотеки может выполняться в обработчике события OnCreate формы, на которой будет выводиться изображение. Для возможности использования функций и процедур библиотеки OpenGL необходимо указать модуль opengl.pas в разделе uses каждого модуля, в котором они будут использоваться. Ниже приведен пример инициализации библиотеки OpenGL.

implementation
{$R *.dfm}
Uses OpenGL;
Const
  //угол поворота изображения при нажатии на клавишу
  AngleDl=5; 
// глобальные переменные
var
  hrc: HGLRC;
  dc: HDC;
  // переменные для хранения текущих углов поворота изображения
  AngleX, AngleY, AngleZ: integer;
procedure TForm1.FormCreate(Sender: TObject);
var PFD: TPixelFormatDescriptor;
  i: integer;
begin
  // получение контекста устройства с помощью системной функции GetDC
  dc:=GetDC(handle);
  // обнуление структуры pfd
  FillChar(PFD, SizeOf(PFD),0);
  pfd.dwFlags  := PFD_DRAW_TO_WINDOW 
    or PFD_SUPPORT_OPENGL or PFD_DOUBLEBUFFER;
  // запрос у операционной системы наиболее подходящего формата пиксела
  i:=ChoosePixelFormat(dc, @PFD);
  if i=0 then
    raise Exception.Create('Не определен формат пиксела !');
  // установка в качестве текущего формата пиксела, полученного с помощью 
  // ф-ии  ChoosePixelFormat
  if not SetPixelFormat(dc, i, @PFD) then
    raise Exception.Create('Ошибка при установке формата пиксела !');
  // создание контекста воспроизведения для библиотеки OpenGL
  // и сохранение его   дескриптора в глобальной переменной
  hrc:=wglCreateContext(dc);
  if hrc=0 then
    raise Exception.Create('Ошибка создания контекста воспроизведения !');
  // установка текущего контекста воспроизведения
  if not wglMakeCurrent(dc, hrc) then
    raise 
      Exception.Create('Невозможно установить текущий контекст воспроизведения !');
  glEnable(GL_DEPTH_TEST);
end;

В листинге 3.1 объявляются глобальные переменные ). Большинство процедур и функций в листинге 3.1 не входят в состав OpenGL и являются функциями операционной системы. В частности функции, названия которых начинаются с последовательности символов "wgl", также являются системными и предназначены для поддержки возможностей OpenGL в операционной системе Windows.

При разработке программ на языке программирования Object Pascal c использованием библиотеки визуальных компонентов (VCL) системные функции использовать приходится довольно редко, так как набор классов библиотеки VCL позволяет этого избежать. При работе с библиотекой OpenGL потребуется несколько системных функций. В процедуре FormCreate с помощью системной функции GetDC выполняется получение дескриптора контекста устройства. Функция GetDC позволяет получить параметры вывода изображения, которые используются для формы. Информация о форме передается в функцию с помощью дескриптора формы, который возвращается свойством формы Handle.

Процедура FillChar также является системной и используется для побайтного заполнения области памяти указанного размера необходимым значением.

procedure FillChar(var Dest; count: Integer; Value: Char);

Процедура имеет следующие параметры:

В листинге 3.1 для определения размера структуры PFD используется функция

function SizeOf(X): Integer;

Функция возвращает размер в байтах переменной или типа данных, переданных ей в качестве параметра X.

Для работы с библиотекой OpenGL операционная система определяет наиболее подходящие параметры вывода изображения, основные из которых перечислены ниже:

Эти параметры задаются с помощью значений полей структуры TPixelFormatDescriptor. Для разных приложений могут потребоваться различные варианты сочетаний этих параметров. Некоторые сочетания могут быть невозможны или не поддерживаться аппаратной платформой или операционной системой. Для того чтобы определить доступный вариант сочетания этих параметров реализуется диалог между программой и операционной системой: программа указывает, какие параметры ей необходимы и передает запрос операционной системе на возможность их использования. Операционная система анализирует возможности оборудования и возвращает приложению наиболее подходящую конфигурацию из возможных вариантов. Программа может проанализировать эту конфигурацию и определить возможность её использования. После выбора приложением подходящей конфигурации для работы библиотеки OpenGL эти параметры устанавливаются текущими.

Для запроса у операционной системы наиболее подходящей конфигурации библиотеки OpenGL для работы приложения используется функция

function ChoosePixelFormat(DC: HDC; p2: PPixelFormatDescriptor): Integer;

Назначение параметров функции:

Функция возвращает номер наиболее подходящей конфигурации библиотеки OpenGL. Операционная система Windows предоставляет ограниченное количество возможных вариантов параметров работы библиотеки OpenGL. Каждое из таких сочетаний имеет свой уникальный целочисленный номер. Один из таких номеров и возвращает функция ChoosePixelFormat.

В выше приведенном примере () поля структуры TPixelFormatDescriptor в переменной PFD заполняются нулевыми значениями с помощью процедуры FillChar, и затем поле dwFlags инициализируется для использования библиотекой OpenGL вторичного буфера.

function SwapBuffers(DC: HDC): BOOL;

Пример её использования приведен в листинге 3.3 .

Для установки выбранного значения формата пиксела используется функция:

function SetPixelFormat(DC:HDC;PixelFormat:Integer;
FormatDef: PPixelFormatDescriptor): BOOL;

Назначение параметров функции:

DC – контекст устройства, полученный с помощью системной функции GetDC.

PixelFormat – номер формата пиксела, полученный с помощью функции ChoosePixelFormat.

FormatDef – указатель на переменную типа TPixelFormatDescriptor, в которой должны быть значения, соответствующие выбранному номеру формата пиксела, который указан в качестве значения параметра PixelFormat.

После задания формата пиксела должен быть создан контекст воспроизведения библиотеки OpenGL для выбранной формы с помощью функции

function wglCreateContext(DC: HDC): HGLRC;

Функции передается единственный параметр DC – контекст устройства, полученный с помощью системной функции GetDC. Функция возвращает дескриптор контекста воспроизведения.

Приложение может иметь несколько контекстов воспроизведения, например, для отображения нескольких проекций одной и той же сцены. Для того чтобы вывести изображение в одной из областей воспроизведения необходимо сделать текущим ассоциированный с ней контекст воспроизведения. Для этого используется функция wglMakeCurrent. Если в приложении всего один контекст воспроизведения, то достаточно сделать его текущим при инициализации библиотеки OpenGL.

function wglMakeCurrent(DC: HDC; p2: HGLRC): BOOL;

Назначение параметров функции:

Функция возвращает логическое значение, информирующее об успешности выполнения операции.

В листинге 3.1 после инициализации библиотеки вызывается процедура glEnable со значением параметра GL_DEPTH_TEST, который включает тест глубины.

Тест глубины реализует отбор примитивов и их фрагментов при формировании изображения в зависимости от удаленности от наблюдателя и выполняет удаление фрагментов, которые заслоняют примитивы, находящиеся ближе к точке наблюдения. При отключенном тесте глубины (по умолчанию после инициализации библиотеки) библиотека не выполняет анализ того, какой из примитивов не виден наблюдателю. Примитивы отображаются в порядке их формирования и поэтому примитивы, которые были сформированы последними, будут "заслонять" другие примитивы в не зависимости от их реальной удалённости от наблюдателя.

Определение области вывода изображения и матрицы проекции

Определение области вывода является необходимым для вывода изображения. Без определения области вывода изображение не будет отображаться. Область вывода изображения определяется с помощью команды OpenGL:

Viewport (x,y: GLint; width, height: GLsizei)

В приведённых ниже примерах выполняется определение матрицы проекции с помощью команды .

Библиотека OpenTK, C#

В библиотеке OpenTK для этого применяется статический метод класса GL (C#):

void Viewport(int x, int y, int width, int height);

Координаты области вывода задаются относительно компонента GLControl и область вывода ограничивается размерами этого компонента.

Параметры команды имеют следующие значения:

Обычно вызов метода ).

private void glControl1_Resize(object sender, EventArgs e)
{
GL.Viewport(0, 0, glControl1.Width, glControl1.Height);
GL.MatrixMode(MatrixMode.Projection);
GL.LoadIdentity();
GL.Ortho(-1, 1, -1, 1, -1, 1);
GL.MatrixMode(MatrixMode.Modelview);
glControl1.Invalidate();
}

В конце листинга 3.2 вызывается метод компонента GLControl:

void Invalidate();

Метод инициализирует событие Paint компонента GLControl, в обработчике которого выполняется обновление изображения с учетом изменения размеров компонента.

Object Pascal (Delphi)

В программе на Object Pascal для реализации команды Viewport используется процедура:

procedure glViewport (x,y: GLint; width, height: GLsizei);

Команда определяет область вывода изображения в координатах окна, для которого был установлен текущий контекст отображения с помощью функции wglMakeCurrent.

Параметры команды имеют следующие значения:

Обычно вызов процедуры ). Это позволяет корректировать размеры области вывода в соответствии с размерами формы.

procedure TForm1.FormResize(Sender: TObject);
begin
  // Установка области вывода
  glViewPort (0, 0, ClientWidth, ClientHeight);
  // задание матрицы проекции
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity;
  glOrtho(-1, 1, -1, 1, -1, 1);
  glMatrixMode(GL_MODELVIEW);
  // перерисовка изображения
  InvalidateRect(Handle, nil, False);
end;

В листинге 3.3 выполняется вывод изображения на всю клиентскую часть формы, поэтому в качестве параметров процедуры glViewPort указываются размеры клиентской области формы: ClientWidth и ClientHeight.

В конце обработчика ) вызывается системная функция:

function InvalidateRect(hWnd: HWND; lpRect: PRect; bErase: BOOL): BOOL;

Она используется для перерисовки изображения после изменения размера области вывода. Функция InvalidateRect посылает форме, дескриптор которой передается в качестве первого параметра hWnd, сообщение, которое приводит к возникновению события OnPaint. В обработчике события OnPaint формируется изображение. Второй параметр определяет прямоугольную область формы для обновления. Если это значение равно nil, то обновляется вся клиентская область формы. Последний параметр bErase определяет: будет ли операционная система обновлять фон формы. При выводе изображения средствами OpenGL это не требуется, поэтому этот параметр равен False.

Основная функция формирования изображения

Формирование изображения выполняется при каждом обновлении изображения формы в программе на Object Pascal (Delphi) и обновлении изображения компонента GLControl библиотеки OpenTK в программе на C#. Обычно для этого используется обработчик события формы OnPaint в программе на Object Pascal (Delphi) и обработчик события Paint компонента GLControl в программе на C#.

Ниже приведены примеры соответствующих обработчиков событий ( и ).

procedure TForm1.FormPaint(Sender: TObject);
begin
  glClearColor (0.5, 0.5, 0.75, 1.0); // цвет фона
  // очистка буферов цвета и глубины
  glClear (GL_COLOR_BUFFER_BIT + GL_DEPTH_BUFFER_BIT);
  // поворот изображения
  glLoadIdentity;
  glRotatef(AngleX, 1.0, 0.0, 0.0);
  glRotatef(AngleY, 0.0, 1.0, 0.0);
  glRotatef(AngleZ, 0.0, 0.0, 1.0);
  // формирование изображения
  glBegin (GL_LINES);
    glColor3f(1, 0, 0); glVertex3f (-1, 0, 0); glVertex3f (1, 0, 0);
    glColor3f(0, 1, 0); glVertex3f (0, -1, 0); glVertex3f (0, 1, 0);
    glColor3f(0, 0, 1); glVertex3f (0, 0, -1); glVertex3f (0, 0, 1);
  glEnd;
  // завершение формирования изображения
  glFlush;
  glFinish;
  SwapBuffers(DC);
end;

private void glControl1_Paint(object sender, PaintEventArgs e)
{
GL.ClearColor(0.5f, 0.5f, 0.75f, 1.0f); // цвет фона
// очистка буферов цвета и глубины
GL.Clear(ClearBufferMask.ColorBufferBit | ClearBufferMask.DepthBufferBit);
// поворот изображения
GL.LoadIdentity();
GL.Rotate(AngleX, 1.0, 0.0, 0.0);
GL.Rotate(AngleY, 0.0, 1.0, 0.0);
GL.Rotate(AngleZ, 0.0, 0.0, 1.0);
// формирование изображения
GL.Begin(BeginMode.Lines);
GL.Color3(1f, 0f, 0f); GL.Vertex3(-1f, 0f, 0f); GL.Vertex3(1f, 0f, 0f);
GL.Color3(0f, 1f, 0f); GL.Vertex3(0f, -1f, 0f); GL.Vertex3(0f, 1f, 0f);
GL.Color3(0f, 0f, 1f); GL.Vertex3(0f, 0f, -1f); GL.Vertex3(0f, 0f, 1f);
GL.End();
// завершение формирования изображения
GL.Flush();
GL.Finish();
glControl1.SwapBuffers();
}

В листингах 3.4 и сначала вызывается команда ClearColor, которая определяет цвет фона изображения. В качестве параметров указываются красная (параметр red), зеленая (параметр green) и синяя (параметр blue) составляющие цвета:

ClearColor (red, green, blue, alpha: GLclampf)

procedure glClearColor (red, green, blue, alpha: GLclampf);

void ClearColor(float red, float green, float blue, float alpha);

Clear (mask: GLbitfield)

procedure glClear (mask: GLbitfield);

В листинге 3.5 в качестве параметра процедуры glClear передается сумма двух констант:

GL_COLOR_BUFFER_BIT – буфер цвета, в котором формируется изображение;

GL_DEPTH_BUFFER_BIT – буфер глубины, который используется для отбора примитивов в зависимости от удалённости от точки наблюдения (см. раздел 3.1).

В C# для реализации команды Clear используется статический метод класса GL библиотеки OpenTK:

void Clear(ClearBufferMask mask);

Значение параметра mask представляет собой перечисление типа ClearBufferMask. Для очистки буферов цвета и глубины используется сумма двух значений:

Далее в листингах 3.4 и формируется изображение трех отрезков разного цвета, направление которых совпадает с направлением декартовых осей координат в пространстве.

procedure glBegin (mode: GLenum);

void Begin(BeginMode mode);

procedure glVertex3f (x,y,z: GLfloat);

void Vertex3(float x, float y, float z);

procedure glEnd;

void End();

В листинге 3.5 для выполнения этой команды вызывается процедура:

procedure glColor3f (red, green, blue: GLfloat);

В примере программы на C# () для этого используется один из статических методов класса GL:

void Color3(float red, float green, float blue);

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  case Key of
    VK_INSERT: inc(AngleX, AngleDl);
    VK_DELETE: dec(AngleX, AngleDl);
    VK_HOME: inc(AngleY, AngleDl);
    VK_END: dec(AngleY, AngleDl);
    VK_PRIOR: inc(AngleZ, AngleDl);
    VK_NEXT: dec(AngleZ, AngleDl);
  end;
  InvalidateRect(Handle, nil, False);
end;

private void glControl1_KeyDown(object sender, KeyEventArgs e)
{
switch(e.KeyCode)
{
case Keys.Insert: AngleX += AngleDl; break;
case Keys.Delete: AngleX -= AngleDl; break;
case Keys.Home: AngleY += AngleDl; break;
case Keys.End: AngleY -= AngleDl; break;
case Keys.Prior: AngleZ += AngleDl; break;
case Keys.Next: AngleZ -= AngleDl; break;
}
glControl1.Invalidate(); 
}

Фрагмент кода, выполняющий эти действия приведен ниже ().

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if not wglMakeCurrent(0, 0) then
    raise Exception.Create(
      'Невозможно освободить текущий контекст воспроизведения !');
  if not wglDeleteContext(hrc) then
    raise Exception.Create('Ошибка удаления контекста воспроизведения !');
  if ReleaseDC(Form1.Handle, dc)=0 then
    raise Exception.Create('Ошибка удаления контекста устройства');
end;

При использовании библиотеки OpenTK завершение работы с библиотекой OpenGL выполняет сама библиотека OpenTK. При этом она выполняет операции, аналогичные приведённым в листинге 3.8 для приложения на Object Pascal (Delphi).

Краткие итоги

В лекции рассмотрена структура приложений, использующих библиотеку OpenGL для формирования изображений, на языке программирования C# с использованием библиотеки OpenTK и на языке программирования Object Pascal. Рассмотрено назначение вторичного буфера и теста глубины. В созданных приложениях реализована обработка клавиатуры для изменения изображения.

Библиотека OpenTK скрывает практически весь процесс инициализации библиотеки OpenGL.

В Object Pascal весь процесс инициализации OpenGL необходимо реализовать непосредственно в программе, при этом есть возможность полного контроля данного процесса.