Разработка бухгалтерской подсистемы

Мы собираемся заполнять поле Период в таблице автоматически, устанавливая период равным дате документа. Для этого сначала уберем поле период из таблицы, удалив его из окна Элементы, после чего создадим в модуле объекта процедуру ПередЗаписью(), приведем ее к следующему виду:

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)
  Для каждого Проводка из Движения.Хозрасчетный Цикл
    Проводка.Период = Дата;
  КонецЦикла;
КонецПроцедуры

Теперь решим следующую задачу. В текущей редакции документа БухгалтерскаяОперация для того, чтобы бухгалтерская запись, приведенная в документе, не оказывала влияния на бухгалтерский учет, то есть, например, не попадала в отчеты, не влияла на состояние остатков по счетам и т.д., нам нужно либо удалить эту запись из документа, либо, если речь идет обо всех записях, которые формирует документ, удалить сам документ. Так поступать не очень удобно – возможно, нам нужно лишь проверить состояние учета без этих, временно ненужных проводок, потом – с ними, и для проведения этой, вполне обычной, операции нам понадобится сначала удалять записи, потом снова создавать.

Лучший выход – возможность произвольного включения и отключения активности проводок. Однако, в табличном поле редактирование поля Активность по умолчанию недоступно. Попытка отключить активность отдельной проводки в документе приводит к ошибке при его записи. Можно включить редактирование этого поля (переместив реквизит Активность со вкладки Реквизиты на вкладку Элементы), но при необходимости отключения активности проводок, придется вручную редактировать это свойство для каждой из них, что не очень удобно. Для того чтобы проводки в документе можно было бы "отключать", не удаляя их, можно доработать форму документа таким образом, чтобы можно было по нажатию одной кнопки включать или отключать активность всех проводок.

В конструкторе форм добавим новую команду, назовем ее Активность, создадим ее обработчик, перетащим эту команду на командную панель формы, где она, по умолчанию, будет представлена в виде кнопки. Обработчик команды будет объявлен с директивой компиляции НаКлиенте, для работы с коллекцией движений объекта нам понадобится серверная процедура или функция. В итоге мы приходим к такому коду:

НаКлиенте
Процедура Активность(Команда)
  ПереключитьАктивностьПроводок();
КонецПроцедуры

НаСервере
Процедура ПереключитьАктивностьПроводок()
  Записи = Объект.Движения.Хозрасчетный;
  Если Записи.Количество()>0 Тогда
    Для каждого Запись из Записи Цикл
      Запись.Активность=НЕ Запись.Активность;
    Конеццикла;  
  КонецЕсли;
 КонецПроцедуры

Здесь мы получаем в переменную Записи набор записей по регистру Хозрасчетный, после чего, в цикле обхода записей, инвертируем их признак Активность. То есть, если до нажатия на кнопку Активность флаг Активность установлен, мы его сбрасываем, если сброшен – устанавливаем.

Для того, чтобы пользователь мог видеть, активны ли проводки, перетащим поле Активность с вкладки Реквизиты на вкладку Элементы в состав реквизитов табличного поля и установим для этого поля свойство Только просмотр.

Вот как, в итоге, выглядит форма нашего доработанного документа в режиме 1С:Предприятие (рис 2.4) после того, как мы ввели в него некоторые данные и однократно нажали на кнопку Активность в панели управления табличного поля. По умолчанию флаг Активность установлен, нажатие привело к сбрасыванию этого флага.

Часто, в реально существующих конфигурациях, документ, подобный только что созданному, используют для ввода начальных остатков по счетам бухгалтерского учета.

Предположим, что пользователь конфигурации решил ввести с его помощью начальные остатки по счетам на конец 2010 года. Пусть это будут следующие остатки:

Капитал: 103000 руб.
Расчеты с поставщиками: 20000 руб. (ООО "Полет")
Касса: 29000 руб.
Расчеты с покупателями: 82000 руб. (ООО "Покупатель")
Материалы для производства: 
    УФ-гель (Петров П.П. (Парикмахерская)), 
    Сумма – 12000, 
    количество – 10 упаковок.

Несложно заметить, что сумма остатков по пассивным счетам (Капитал и Поставщики) равняется сумме остатков по активным (Касса, Покупатели, Материалы). Такие остатки принято вводить в корреспонденции со счетом )

После нажатия на кнопку Записать и закрыть, новый счет будет добавлен в план счетов, мы сможем пользоваться им при составлении проводок.

Создадим в пользовательском режиме новый документ Бухгалтерская операция. Установим дату – 31.12.2010, время – 23:59:59. Начальные остатки обычно вводят именно такой датой. Заполним табличное поле документа в соответствии с вышеприведенными данными.

При вводе записей с помощью документа Бухгалтерская операция система автоматически ограничивает ввод данных в поля табличной части после указания счета дебета или счета кредита таким образом, чтобы мы не могли ввести то, что не нужно при формировании проводки по данному счету. Например, в случае со счетом 00 мы можем ввести лишь сам счет и сумму по нему, в случае со счетом Материалы для производства мы можем, помимо данных о счете и сумме, заполнить сведения о двух субконто, о количестве материалов.

Отчет Оборотно-сальдовая ведомость

После того, как мы ввели начальные остатки по счетам, создадим инструмент для анализа состояния учета, один из базовых бухгалтерских отчетов – Оборотно-сальдовую ведомость. Этот отчет должен предоставлять нам следующие данные за определенный период:

Добавим в систему новый отчет, назовем его ОборотноСальдоваяВедомость, добавим отчет в подсистему БухгалтерскийУчет, на закладке Основные создадим основную схему компоновки данных. В конструкторе СКД добавим новый набор данных – Запрос.

Воспользуемся .

Счет
СуммаНачальныйОстатокДт
СуммаНачальныйОстатокКт
СуммаОборотДт
СуммаОборотКт
СуммаКонечныйОстатокДт
СуммаКонечныйОстатокКт

Выбрав указанные поля, нажмем в окне конструктора запроса кнопку ОК. Теперь, на закладке окна конструктора СКД Наборы данных для полей СуммаНачальныйОстатокДТ, СуммаНачальныйОстатокКТ, СуммаКонечныйОстатокДТ, СуммаКонечныйОстатокКТ, установим свойство Роль в значение . Без этой установки система неправильно сформирует нужный нам отчет, а именно, при настройках по умолчанию не будет формировать итоговые показатели по начальным и конечным остаткам (сальдо), а оборотно-сальдовая ведомость должна содержать подобные показатели, которые обычно используют для контроля выводимых данных.

Теперь в конструкторе СКД перейдем на закладку Ресурсы, нажмем на кнопку добавления всех ресурсов (на ней изображены две стрелки, направленные вправо). В состав ресурсов будут добавлены все поля, кроме поля Счет. На закладке Настройки включим отображение параметров Начало периода и Конец периода в пользовательском интерфейсе (кнопка Свойства элемента пользовательских настроек).

Воспользуемся конструктором настроек компоновки данных, добавим новый отчет. Тип отчета – :

Счет
СуммаНачальныйОстатокДт
СуммаНачальныйОстатокКт
СуммаОборотДт
СуммаОборотКт
СуммаКонечныйОстатокДт
СуммаКонечныйОстатокКт

В окне настройки группировки отчета в поле Строки добавим поле Счет. В качестве типа группировки выберем Иерархия – нам хотелось бы, чтобы данные по счетам выводились с учетом иерархии счетов.

В качестве поля для упорядочения таблицы выберем поле ), направление сортировки – по возрастанию.

Теперь откроем отчет в 1С:Предприятие и посмотрим, как он будет выглядеть, рис 2.10.

Как видите, наш отчет выводит все необходимые данные, счета отсортированы в соответствии с их порядком, итоги по показателям подсчитаны и выведены, счета представлены в соответствии с их иерархией.

Выше, создавая подсистему учета, мы указали в настройках плана счетов, что максимальное количество субконто счета равняется трем. В бухгалтерском учете хозрасчетных организаций обычно применяется до трех субконто. Создавая предопределенные счета, мы определяли для них не более двух субконто. Однако, пользователь, при необходимости, может определить дополнительные субконто в режиме 1С:Предприятие.

Предположим, организации понадобился новый счет с кодом 10.3, который планируется использовать для учета специальной одежды, выданной сотрудникам организации. Этот счет должен иметь три субконто:

В соответствии с особенностями работы, в организации выделяется три группы спецодежды.

Запустим систему в режиме 1С:Предприятие, откроем План счетов. Создадим новый счет, заполним его параметры следующим образом:

Код: 10.3
Наименование: "Спецодежда"
Порядок: 10. 3
Вид: Активный
Родитель: Материалы
Признак Количественный: Установлен

Добавим в его список субконто два предопределенных субконто – .

Как производить записи по этому счету? У пользователя, без использования конфигуратора, есть лишь одна возможность – применить документ .

Сформируем бухгалтерскую запись, показывающую поступление спецодежды со следующими параметрами

Счет Дт: Спецодежда
Субконто1 Дт: Одежда для парикмахера
Субконто2 Дт: Иванов И.И. (Парикмахерская)
Субконто3 Дт: Первая группа
Количество Дт: 5 
Счет Кт: Расчеты с поставщиками в валюте
Субконто1 Кт: ООО "Полет"
Валюта Кт: USD
Валютная сумма Кт: 500
Сумма: 15000
Содержание: Поступила спецодежда, оплата в валюте

После записи документа построим .

Проведение документа Поступление

Займемся документом ПоступлениеМатериалов, подготовим его к проведению по бухгалтерскому учету.

Добавим к документу новый реквизит, назовем его Валюта, тип – СправочникСсылка.Валюта. В этом реквизите мы будем указывать валюту документа.

Кроме того, создадим реквизит СчетУчета, тип – ПланСчетовСсылка.Хозрасчетный. Используя этот реквизит, мы будем задавать счет, на который следует принять материалы, перечисленные в документе. Документ можно будет проводить либо по счету Материалы для производства, либо – по счету Прочие материалы. Выбор другого счета в данном поле будет восприниматься системой как ошибочный.

На закладке Движения укажем, что документ будет проводиться по регистру бухгалтерии Хозрасчетный.

Добавим документ в состав подсистемы БухгалтерскийУчет.

Откроем форму документа и разместим в форме новые реквизиты .

Теперь мы можем заняться процедурой проведения документа.

При ее конструировании нужно учесть то, что при указании валюты в реквизите Валюта документ будет проводиться по счету расчетов с поставщиками в валюте, если валюта в поле не указана – по счету учета в рублях. Кроме того, подразумевается, что указав валюту в реквизите Валюта мы вводим в табличную часть документа сведения о стоимости материалов в валюте, то есть, для заполнения "рублевых" полей в записях нам понадобится конвертировать валютные суммы в рублевые.

Сейчас процедура проведения нашего документа, который до этого выполнял движения лишь по регистру накопления ОстаткиМатериалов, выглядит следующим образом:

Процедура ОбработкаПроведения(Отказ, Режим)
  Движения.ОстаткиМатериалов.Записывать = Истина;
  Для Каждого ТекСтрокаМатериалы Из Материалы Цикл
    Движение = Движения.ОстаткиМатериалов.Добавить();
    Движение.ВидДвижения = ВидДвиженияНакопления.Приход;
    Движение.Период = Дата;
    Движение.Номенклатура = ТекСтрокаМатериалы.Номенклатура;
    Движение.ОтветственныйСотрудник = ОтветственныйСотрудник;
    Движение.Количество = ТекСтрокаМатериалы.Количество;
    Движение.Сумма = ТекСтрокаМатериалы.Сумма;
  КонецЦикла;
КонецПроцедуры

Нам придется полностью переработать эту процедуру, так как, во-первых, нас теперь интересует не только проведение по регистру накопления ОстаткиМатериалов, но и по регистру бухгалтерии Хозрасчетный, а во-вторых – в том случае, если в документе указана валюта взаиморасчетов, нам, прежде чем формировать движения по регистрам, придется конвертировать суммовые данные, введенные в документе, из валюты документа в рубли.

В итоге мы пришли к такому коду процедуры проведения документа ПоступлениеМатериалов:

Процедура ОбработкаПроведения(Отказ, Режим)
  //Переменная для хранения курса валюты
  Перем КурсВалюты;
  //Проверим, указан ли один из необходимых счетов
  //Для учета номенклатуры
  Если СчетУчета<>ПланыСчетов.Хозрасчетный.ПрочиеМатериалы И 
    СчетУчета<>ПланыСчетов.Хозрасчетный.МатериалыДляПроизводства Тогда
    Сообщить("Нужно указать либо счет Прочие материалы, либо счет Материалы для производства");
    Отказ=Истина;
    Возврат;
  КонецЕсли;
  //Проверим, указана ли в документе валюта
  Если Валюта = Справочники.Валюты.ПустаяСсылка() Тогда
  //Формирование движений по документу, данные в котором
  //заданы в рублях
  //Получаем табличную часть текущего документа, сгруппированную по полю Номенклатура
  Запрос = Новый Запрос;
  Запрос.Текст = 
    "ВЫБРАТЬ
    |  ПоступлениеМатериаловМатериалы.Номенклатура,
    |  СУММА(ПоступлениеМатериаловМатериалы.Количество) КАК Количество,
    |  СУММА(ПоступлениеМатериаловМатериалы.Сумма) КАК Сумма
    |ИЗ
    |  Документ.ПоступлениеМатериалов.Материалы КАК ПоступлениеМатериаловМатериалы
    |ГДЕ
    |  ПоступлениеМатериаловМатериалы.Ссылка.Ссылка = Ссылка
    |
    |СГРУППИРОВАТЬ ПО
    |  ПоступлениеМатериаловМатериалы.Номенклатура";
   Запрос.УстановитьПараметр("Ссылка", Ссылка);
    Результат = Запрос.Выполнить();
     ВыборкаДетальныеЗаписи = Результат.Выбрать();
    Движения.ОстаткиМатериалов.Записывать = Истина;
  Движения.Хозрасчетный.Записывать=Истина;
  Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
  //Формируем движения по регистру накопления ОстаткиМатериалов  
    Движение = Движения.ОстаткиМатериалов.Добавить();
    Движение.ВидДвижения = ВидДвиженияНакопления.Приход;
    Движение.Период = Дата;
    Движение.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;
    Движение.ОтветственныйСотрудник = ОтветственныйСотрудник;
    Движение.Количество = ВыборкаДетальныеЗаписи.Количество;
    Движение.Сумма = ВыборкаДетальныеЗаписи.Сумма;
  //Формируем движения по регистру бухгалтерии Хозрасчетный
    Движение=Движения.Хозрасчетный.Добавить();
    Движение.Период=Дата;
    Движение.СчетДт=СчетУчета;
    Движение.СубконтоДт[ПланыВидовХарактеристик.ВидыСубконто.Номенклатура]=
           ВыборкаДетальныеЗаписи.Номенклатура;
    Движение.СубконтоДт[ПланыВидовХарактеристик.ВидыСубконто.Сотрудники]=
           ОтветственныйСотрудник;
    Движение.КоличествоДт=ВыборкаДетальныеЗаписи.Количество;
    Движение.СчетКт=ПланыСчетов.Хозрасчетный.РасчетыСПоставщикамиВРублях;
    Движение.СубконтоКт[ПланыВидовХарактеристик.ВидыСубконто.Контрагенты]=
           Контрагент;
    Движение.Сумма=ВыборкаДетальныеЗаписи.Сумма;
  КонецЦикла;
    Иначе
  //Формирование движений по документу, данные в котором
  //заданы в валюте
  //Получаем курс валюты, заданной в документе
  Запрос = Новый Запрос;
  Запрос.Текст = 
    "ВЫБРАТЬ
    |  КурсыВалютСрезПоследних.Курс
    |ИЗ
    |  РегистрСведений.КурсыВалют.СрезПоследних(МоментВремени, Валюта = Валюта) КАК КурсыВалютСрезПоследних";

  Запрос.УстановитьПараметр("Валюта", Валюта);
  Запрос.УстановитьПараметр("МоментВремени", МоментВремени());
     Результат = Запрос.Выполнить();
    ВыборкаДетальныеЗаписи = Результат.Выбрать();
    Если ВыборкаДетальныеЗаписи.Следующий() Тогда
    КурсВалюты=ВыборкаДетальныеЗаписи.Курс;
  Иначе
    Сообщить("Не найден курс валюты!");
    Отказ=Истина;
    Возврат;
  КонецЕсли;
  //Получаем табличную часть текущего документа, сгруппированную по полю Номенклатура
  Запрос = Новый Запрос;
  Запрос.Текст = 
    "ВЫБРАТЬ
    |  ПоступлениеМатериаловМатериалы.Номенклатура,
    |  СУММА(ПоступлениеМатериаловМатериалы.Количество) КАК Количество,
    |  СУММА(ПоступлениеМатериаловМатериалы.Сумма) КАК Сумма
    |ИЗ
    |  Документ.ПоступлениеМатериалов.Материалы КАК ПоступлениеМатериаловМатериалы
    |ГДЕ
    |  ПоступлениеМатериаловМатериалы.Ссылка.Ссылка = Ссылка
    |
    |СГРУППИРОВАТЬ ПО
    |  ПоступлениеМатериаловМатериалы.Номенклатура";

  Запрос.УстановитьПараметр("Ссылка", Ссылка);
    Результат = Запрос.Выполнить();
     ВыборкаДетальныеЗаписи = Результат.Выбрать();
    Движения.ОстаткиМатериалов.Записывать = Истина;
  Движения.Хозрасчетный.Записывать=Истина;
  Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
  //Формируем движения по регистру накопления ОстаткиМатериалов  
    Движение = Движения.ОстаткиМатериалов.Добавить();
    Движение.ВидДвижения = ВидДвиженияНакопления.Приход;
    Движение.Период = Дата;
    Движение.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;
    Движение.ОтветственныйСотрудник = ОтветственныйСотрудник;
    Движение.Количество = ВыборкаДетальныеЗаписи.Количество;
    Движение.Сумма = ВыборкаДетальныеЗаписи.Сумма*КурсВалюты;
  //Формируем движения по регистру бухгалтерии Хозрасчетный
    Движение=Движения.Хозрасчетный.Добавить();
    Движение.Период=Дата;
    Движение.СчетДт=СчетУчета;
    Движение.СубконтоДт[ПланыВидовХарактеристик.ВидыСубконто.Номенклатура]=
           ВыборкаДетальныеЗаписи.Номенклатура;
    Движение.СубконтоДт[ПланыВидовХарактеристик.ВидыСубконто.Сотрудники]=
           ОтветственныйСотрудник;
    Движение.КоличествоДт=ВыборкаДетальныеЗаписи.Количество;
    Движение.СчетКт=ПланыСчетов.Хозрасчетный.РасчетыСПоставщикамиВВалюте;
    Движение.СубконтоКт[ПланыВидовХарактеристик.ВидыСубконто.Контрагенты]=
           Контрагент;
    Движение.ВалютаКт=Валюта;
    Движение.ВалютнаяСуммаКт=ВыборкаДетальныеЗаписи.Сумма;
    Движение.Сумма=ВыборкаДетальныеЗаписи.Сумма*КурсВалюты;
  КонецЦикла;
   КонецЕсли;
КонецПроцедуры

В первую очередь мы проверяем является ли счет учета материалов, указанный в документе, одним из тех счетов, по которым мы планируем его проводить. В нашем случае это пара счетов – Прочие материалы и Материалы для производства. Они являются предопределенными элементами плана счетов Хозрасчетный, поэтому мы можем обращаться к ним по именам непосредственно из кода.

Если выбранный счет не относится к тем, движения по которым выполняет документ, мы выдаем пользователю сообщение об ошибке, отказываемся от проведения документа и выходим из процедуры проведения.

Дальнейшая работа процедуры проведения документа делится на две ветви. Первая ветвь выполняется в том случае, если валюта в реквизите Валюта не указана. При таком варианте развития событий валюта документа принимается за валюту регламентированного учета, движения формируются в рублях без пересчета.

В первой ветви мы получаем из табличной части документа данные о номенклатурных позициях, их количестве и общей стоимости, сгруппированные по полю Номенклатура, после чего формируем движения по регистру ОстаткиМатериалов (если вас интересуют подробности о проведении документов по регистрам накопления, обратитесь к нашему курсу, который посвящен основам разработки и модификации прикладных решений для платформы 1С:Предприятие 8.2.) и по регистру бухгалтерии Хозрасчетный.

Данные движения по регистру бухгалтерии мы заполняем, пользуясь реквизитами документа и информацией, полученной из выборки. Формируя движения, мы учитываем особенности счетов. Так, по счетам учета материалов ведется количественный учет, эти счета находятся в дебете проводки, значит, нам нужно заполнять свойство КоличествоДт. При заполнении данных по субконто мы так же руководствуемся ранее настроенными свойствами счетов, используя конструкцию следующего вида: Движение.СубконтоДт[ПланыВидовХарактеристик.ВидыСубконто.Сотрудники]. Так как субконто Сотрудники в данном случае является предопределенным элементом плана видов характеристик ВидыСубконто, мы можем обратиться к нему по имени.

Вторая ветвь проведения документа активизируется в том случае, если при проверке реквизита Валюта оказалось, что он не пуст, что подразумевает сразу несколько последствий – данные о цене и сумме приведены в валюте, то есть, требуется их конвертация в рубли, учет данной операции должен вестись на счете валютных расчетов с поставщиками.

Во второй ветви мы, в первую очередь, получаем из регистра сведений КурсыВалют самое свежее значение курса для выбранной валюты на дату проведения документа. В данном случае вся ответственность за корректность курса и за своевременность ввода свежих данных в регистр накопления лежит на пользователе.

Если курс валюты получить не удалось – мы сообщаем пользователю об ошибке, отказываемся от проведения документа и выходим из процедуры. Если же найден – мы записываем его в ранее объявленную переменную КурсВалюты для последующего использования.

Далее во второй ветви мы получаем данные из табличной части документа, сгруппировав их по полю Номенклатура, после чего формируем движения – сначала по регистру накопления ОстаткиМатериалов, конвертируя (Движение.Сумма = ВыборкаДетальныеЗаписи.Сумма*КурсВалюты;) значение суммовой стоимости поступившей номенклатурной позиции в рубли путем умножения валютной суммы на найденный курс валюты.

При формировании движений по регистру бухгалтерии Хозрасчетный, мы проводим документ по счету РасчетыСПоставщикамиВВалюте, что требует от нас указания валюты, расчета суммы движения с учетом курса и указания валютной суммы:

    Движение.ВалютаКт=Валюта;
    Движение.ВалютнаяСуммаКт=ВыборкаДетальныеЗаписи.Сумма;
    Движение.Сумма=ВыборкаДетальныеЗаписи.Сумма*КурсВалюты;

После того, как работа над процедурой проведения завершена, следует проверить проведение документа в режиме 1С:Предприятие, проконтролировав правильность отражения движений в зависимости от указания валюты и выбора счетов учета материалов, а так же – обратив особое внимание на правильное отражение в учете данных о суммах и валютных суммах отраженных операций.

Отчет по остаткам материалов по данным бухучета

Построим отчет, который будет выводить сведения о количественных остатках материалов по данным бухгалтерского учета. Строго говоря, данные о материальных ценностях могут храниться не только на счетах, родителем которых является счет Материалы, но на любых других счетах, которые отличаются, во-первых, тем, что являются активными, во-вторых – тем, что имеют установленный признак учета Количественный, и, в-третьих – тем, что имеют субконто Номенклатура. Построим отчет, исходя из этих соображений.

Добавим в систему новый отчет .

Откроем окно параметров виртуальной таблицы (кнопка ):

УсловиеСчета: Счет.Количественный и Счет.Вид=Активный
Субконто: ВидСубконто

В конструкторе запроса на закладке .

Завершим работу с конструктором запросов, перейдем на закладку Ресурсы конструктора СКД, выберем в качестве ресурса Количество.

Перейдем на закладку Параметры, здесь мы видим три параметра – Период, Активный и ВидСубконто. По умолчанию для двух последних параметров назначены значений .

Нас такое состояние дел не устраивает – укажем (с помощью кнопок Выбрать у соответствующих полей) для параметра Активный значение .

Перейдем на закладку Настройки. Включим отображение поля ввода параметра Период в пользовательском интерфейсе и воспользуемся конструктором настроек для задания внешнего вида отчета. Выберем вид отчета – Таблица. На этапе выбора полей, которые будут отображаться в отчете, укажем поля Номенклатура и Количество. Группировку строк произведем по полю Номенклатура, тип группировки – Иерархия. Поле упорядочивания – Номенклатура, по возрастанию.

Построим отчет в режиме 1С:Предприятие, рис 2.20.

Мы, перед построением отчета, отменили проведение документов, фиксирующих поступление материалов, за исключением, во-первых – документа Бухгалтерская операция, которым мы вводили начальные остатки, во-вторых – документа Бухгалтерская операция, с помощью которого мы сформировали движение по счету Спецодежда, созданному в пользовательском режиме. Результаты соответствуют ожидаемым. Проведение других документов поступления материалов показывают, что отчет правильно выводит нужные данные. В частности, мы провели документ ПоступлениеМатериалов, который отражает поступление различных номенклатурных позиций с одинаковым количеством – ). Надо отметить, что логика нашего решения позволяет принимать к учёту одежду для парикмахера с помощью документа Поступление материалов. Одежда не является, в общепринятом смысле, материалом. В реально используемой конфигурации подобную операцию нужно оформлять либо с помощью бухгалтерской справки и соответствующей ручной правки регистров, либо - разработать для этой цели специальный документ, который позволит отразить механизм учёта, характерный именно для одежды или других подобных объектов учёта.

Выводы

В этой лекции мы разработали документ, позволяющий отражать произвольные бухгалтерские записи в подсистеме бухгалтерского учета, доработали документ ПоступлениеМатериалов таким образом, чтобы он мог использоваться для отражения поступления материалов от поставщиков, расчеты с которыми производятся в рублях, либо в валюте, построили отчеты по регистру бухгалтерии – Оборотно-сальдовую ведомость и Остатки материалов по бухучету с использованием СКД. Мы рассмотрели операции создания, настройки и использования счетов бухгалтерского учета в пользовательском режиме.

В нашей следующей лекцией мы займемся проведением по бухгалтерскому учету документов, отражающих расход материалов и разработкой документа, фиксирующего в учете отклонения, вызванные изменением курсов валют.

Видеоурок

Для данной лекции подготовлен видеоурок.