Работа с принтерами

Щелкните на кнопке Start (Начать) панели инструментов.

Ваша программа запустится на выполнение в среде разработки. Вы увидите такую форму.

Если вы установили файлы примеров в папку по умолчанию c:\vbnet03sbs, щелкните на кнопке Печать графики и распечатайте значок Sun.ico. Если вы не использовали расположение файлов примеров по умолчанию, или если вы хотите распечатать другой графический файл, измените содержимое текстового поля, а затем щелкните на кнопке Print Graphic. Метод DrawImage увеличит изображение до максимального размера, который может быть напечатан на вашем принтере на одной странице, а затем отправит его на принтер. (Эта функция увеличения позволяет лучше рассмотреть изображение.) Если вы хотите изменить расположение или размер распечатки, поищите в справочной системе Visual Basic термин "Graphics.DrawImage", а затем изучите различные доступные аргументы и их значения и измените код программы. Если вы внимательно посмотрите, то увидите, что когда Visual Basic отправляет ваше задание печати на принтер, появляется следующее диалоговое окно.

Это окно состояния также является результатом работы класса PrintDocument и предоставляет пользователям профессионально выглядящий интерфейс печати, включая номер для каждой печатаемой страницы.

Установите для объектов формы следующие свойства:

Ваша форма будет выглядеть примерно так.

Теперь добавьте код программы, необходимый для печати содержимого текстового поля.

Прокрутите код формы в самый верх, а затем введите следующее объявление Imports:

Imports System.Drawing.Printing

Оно определяет пространство имен System.Drawing.Printing, которое требуется для определения класса PrintDocument и необходимых объектов этого класса.

Теперь снова прокрутите код вниз до процедуры события Button1_Click, а затем введите следующий код программы:

'Печать с использованием обработчика ошибок для перехвата проблем
Try
	'Объявляем переменную PrintDoc типа PrintDocument
	Dim PrintDoc As New PrintDocument
	AddHandler PrintDoc.PrintPage, AddressOf Me.PrintText
	PrintDoc.Print()		'печать текста
	Catch ex As Exception	'перехват исключения печати
	MessageBox.Show("Извините, возникли проблемы с печатью", _
	ex.ToString())
End Try

Строки, являющиеся новыми или изменившиеся по сравнению с программой Print Graphics, выделены жирным шрифтом. Вместо того чтобы добавлять элемент управления PrintDocument в вашу форму, на этот раз вы просто создали PrintDocument программно. Для этого вы использовали ключевое слово Dim и тип PrintDocument, который был определен в вашей программе при определении пространства имен System.Drawing.Printing. После этого переменная PrintDoc представляет объект PrintDocument и используется для объявления обработчика ошибок и печати текстового документа. Обратите внимание, что для ясности я переименовал процедуру, которая будет обрабатывать событие печати в PrintText (вместо PrintGraphic ).

Прокрутите процедуру события Button1_Click в Редакторе кода вверх до области глобальных объявлений. Введите следующее объявление Sub-процедуры:

'Sub для печати текста
Private Sub PrintText(ByVal sender As Object, _
	ByVal ev As PrintPageEventArgs)
	'Используем DrawString для создания текста в объекте Graphics
	ev.Graphics.DrawString(TextBox1.Text, New Font("Arial", _
	11, FontStyle.Regular), Brushes.Black, 120, 120)
	'Указываем, что это последняя печатаемая страница
	ev.HasMorePages = False
End Sub

Это процедура, которая обрабатывает событие печати, генерируемое методом PrintDoc.Print. Изменения по сравнению с процедурой PrintGraphic из предыдущего упражнения также выделены жирным шрифтом. При печати текста вы используете новый метод. Вместо использования Graphics.DrawImage, который рисует графическое изображение, вы должны использовать Graphics.DrawString, который печатает текстовую строку. Я указал текст для печати в свойстве Text объекта текстового поля, базовое форматирование (Arial, 11 пунктов, обычный стиль, черный цвет) и координаты (x, y) начала печати на странице, равные (120, 120). Это придает печатной странице внешний вид, похожий на текстовое поле на экране. Как и в прошлый раз, я установил свойство ev.HasMorePages на значение False, чтобы указать, что задание на печать не содержит нескольких страниц.

Щелкните на кнопке Start (Начать) панели инструментов.

Ваша программа запустится в среде разработки.

Введите в текстовое поле какой-нибудь текст. Если вы введете несколько строк, убедитесь, что в конце каждой строки вы ввели возврат каретки. Перенос строк в этой демонстрационной программе не поддерживается - слишком длинные строки будут вылезать за правую границу печати. Ваша форма должна выглядеть примерно так.

Теперь установите для объектов формы следующие свойства:

Ваша форма будет выглядеть примерно так, как показано на рисунке ниже.

Теперь добавьте код программы, необходимый для открытия текстового файла и его печати.

Прокрутите код программы в самое начало и введите следующий код:

Imports System.Drawing.Printing

Эти определения библиотек делают доступными классы для печати.

Переместите курсор под метку "Windows Form Designer generated code" ("Код, автоматически созданный конструктором форм Windows"), а затем введите следующие объявления переменных:

Private PrintPageSettings As New PageSettings
Private StringToPrint As String
Private PrintFont As New Font("Arial", 10)

Эти операторы определяют важную информацию о печатаемых страницах.

Прокрутите код до процедуры события btnOpen_Click, а затем введите следующий код программы:

Dim AllText, LineOfText As String
'отображаем диалоговое окно Открыть
OpenFileDialog1.Filter = "Текстовые файлы (*.TXT)|*.TXT"
OpenFileDialog1.ShowDialog()
If OpenFileDialog1.FileName <> "" Then
	Try 'открываем файл и перехватываем все ошибки с помощью обработчика
		FileOpen(1, OpenFileDialog1.FileName, OpenMode.Input)
		Do Until EOF(1) 'читаем строки из файла
			LineOfText = LineInput(1)
			'добавляем каждую строку в переменную AllText
			AllText = AllText  LineOfText  vbCrLf
		Loop                   'обновляем метку
		RichTextBox1.Text = AllText  'отображаем файл
		RichTextBox1.Select(1, 0)   'удаляем выделение текста
		RichTextBox1.Enabled = True 'включаем текстовый курсор
		'Включаем кнопку Print
		btnPrint.Enabled = True
	Catch ex As Exception
		'display error messages if they appear
		MessageBox.Show(ex.Message)
	Finally
		FileClose(1) 'закрываем файл
	End Try
End If

Когда пользователь щелкает на кнопке Открыть, эта процедура события отображает диалоговое окно Open, используя для него фильтр, который отображает только текстовые файлы. Когда пользователь выбирает файл, имя файла присваивается открытой строковой переменной с именем FilePath, которая объявлена в верхней части процедуры события. Затем процедура использует для загрузки текстового файла в объект RichTextBox1 обработчик ошибок Try...Catch. Наконец, процедура события включает кнопку Print ( btnPrint ), так что пользователь может распечатать файл. Эта процедура открывает файл и включает кнопку печати в форме, но не выполняет самой печати.

Введите следующий код программы:

Try
	'Указываем текущие параметры страницы
	PrintDocument1.DefaultPageSettings = PrintPageSettings
	'Указываем документ для диалогового окна печати и показываем его
	StringToPrint = RichTextBox1.Text
	PrintDialog1.Document = PrintDocument1
	Dim result As DialogResult = PrintDialog1.ShowDialog()
	'Если сделан щелчок на OK, печатаем документ на принтере
	If result = DialogResult.OK Then
		PrintDocument1.Print()
	End If
	Catch ex As Exception
	'Отображаем сообщение об ошибке
	MessageBox.Show(ex.Message)
End Try

Эта процедура события устанавливает параметры принтера по умолчанию для документа и, если пользователь изменил текст в объекте форматированного текста, присваивает содержимое объекта RichTextBox1 строковой переменной StringToPrint (определенной в верхней части кода формы). Затем она открывает диалоговое окно Print и позволяет пользователю настроить любые параметры печати, которые можно изменить (принтер, число копий, опцию печати в файл и т.д.). Если пользователь щелкает на кнопке OK, процедура события посылает задание печати на принтер, вызывая следующий оператор:

PrintDocument1.Print()

Введите в процедуре события PrintDocument1_PrintPage следующий код программы:

Dim numChars As Integer
Dim numLines As Integer
Dim stringForPage As String
Dim strFormat As New StringFormat
'На основании параметров страницы определяем прямоугольную область
'печати
Dim rectDraw As New RectangleF( _
e.MarginBounds.Left, e.MarginBounds.Top, _
e.MarginBounds.Width, e.MarginBounds.Height)
'Определяем область для вычисления объема умещающегося на странице
'текста
'Делаем высоту на одну строку меньше, чтобы гарантировать, что текст не
'будет обрезан
Dim sizeMeasure As New SizeF(e.MarginBounds.Width, _
e.MarginBounds.Height - PrintFont.GetHeight(e.Graphics))

'При печати длинных строк разбиваем их по словам
strFormat.Trimming = StringTrimming.Word
'Вычисляем, сколько символов и строк поместится в области sizeMeasure
e.Graphics.MeasureString(StringToPrint, PrintFont, _
sizeMeasure, strFormat, numChars, numLines)
'Вычисляем строку, которая уместится на странице
stringForPage = StringToPrint.Substring(0, numChars)
'Печатаем строку на текущей странице
e.Graphics.DrawString(stringForPage, PrintFont, _
Brushes.Black, rectDraw, strFormat)
'Если еще есть текст, указываем, что есть следующая страница
If numChars < StringToPrint.Length Then
	'Удаляем из строки уже напечатанный текст
	StringToPrint = StringToPrint.Substring(numChars)
	e.HasMorePages = True
	Else
	e.HasMorePages = False
	'Весь текст был напечатан, так что восстанавливаем строку
	StringToPrint = RichTextBox1.Text
End If

Эта процедура события выполняет собственно печать текстового документа, и делает она это, точно определяя область печати (или прямоугольник области печати) на основе параметров диалогового окна Page Setup. Весь текст, который помещается в этой области, может быть распечатан обычным образом; текст, который выходит за границы этой области, должен быть разбит на несколько строк или страниц, как это происходит в стандартных приложениях Windows.

Область печати определяется с помощью переменной rectDraw, которая основана на классе RectangleF. Для обрезания строк, которые выходят за границу правого поля печати, используются переменная strFormat и метод Trimming. Готовая текстовая строка печатается методом DrawString, которую вы уже использовали в этой лекции. Свойство e.HasMorePages используется для указания того, есть ли еще страницы для печати. Если страниц больше не осталось, свойство HasMorePage устанавливается на значение False, и содержимое переменной StringToPrint становится равным содержимому объекта RichTextBox1.

Щелкните на кнопке Start (Начать) панели инструментов.

Ваша программа запустится на выполнение в среде разработки. Обратите внимание, что кнопка Печать при этом отключена, так как вы еще не выбрали файл.

Перейдите в папку c:\vbnet03sbs\Гл.18, а затем щелкните на файле longFile.txt. Ваше диалоговое окно будет выглядеть так.

Чтобы выбрать этот файл, щелкните на Открыть. Ваша программа загрузит текстовый файл в объект поля форматированного текста, а затем включит кнопку Печать. Этот файл имеет большой размер и в нем есть строки, которые переносятся так, что вы сможете протестировать возможность указания ширины печати и многостраничную печать. Ваша форма будет выглядеть примерно так.

Visual Basic отобразит диалоговое окно Печать, показанное на следующей иллюстрации.

Будут активизированы многие опции диалогового окна Печать, и вы можете поэкспериментировать с ними, как вы делаете это в обычном приложении Windows.

Установите для объектов кнопок формы следующие свойства:

Ваша форма будет выглядеть примерно так.

Введите следующий код программы:

Try
	'Загружаем параметры страницы и отображаем диалоговое окно
	'параметров страницы
	PageSetupDialog1.PageSettings = PrintPageSettings
	PageSetupDialog1.ShowDialog()
	Catch ex As Exception
	'Отображаем сообщение об ошибке
	MessageBox.Show(ex.Message)
End Try

Код для создания диалогового окна Параметры страницы в этой программе довольно прост, так как в верхней части кода формы уже была определена переменная PrintPageSettings. Эта переменная хранит информацию об определении текущей страницы. Когда она присваивается свойству PageSettings объекта PageSetupDialog1, метод ShowDialog автоматически загружает диалоговое окно, которое позволяет пользователю ориентацию страницы, полей и другие параметры страницы. Обработчик ошибок Try...Catch просто обрабатывает все ошибки, которые могут произойти при использовании метода ShowDialog.

Введите следующий код программы:

Try
	'Указываем текущие параметры страницы
	PrintDocument1.DefaultPageSettings = PrintPageSettings
	'Указываем документ для диалогового окна предварительного просмотра
	'и показываем его
	StringToPrint = RichTextBox1.Text
	PrintPreviewDialog1.Document = PrintDocument1
	PrintPreviewDialog1.ShowDialog()
	Catch ex As Exception
	'Отображаем сообщение об ошибке
	MessageBox.Show(ex.Message)
End Try

Аналогичным образом процедура события btnPreview_Click присваивает переменную PrintPageSettings свойству DefaultPageSettings объекта PrintDocument1, а затем копирует текст из объекта форматированного текста в переменную StringToPrint и открывает диалоговое окно Предварительный просмотр. Предварительный просмотр автоматически использует данные параметров страницы для отображения визуального представления документа так, как он будет напечатан - вам не требуется отображать эту информацию вручную. Теперь сделайте небольшое изменение в коде программы в процедуре события btnOpen_Click.

Прокрутите код в конец этой процедуры события непосредственно перед блоком кода Catch и найдите следующий оператор программы:

btnPrint.Enabled = True

Под этим оператором добавьте следующие строки кода:

btnSetup.Enabled = True
btnPreview.Enabled = True

Теперь ваша программа включит кнопки печати, когда будет открыт документ для печати.

Щелкните на кнопке Start (Начать) панели инструментов.

Программа запустится, и будет включена только первая кнопка.

Щелкните на кнопке Открыть, а затем откройте файл longFile.txt, расположенный в папке c:\vbnet03sbs\Гл.18. После этого включатся три остальные кнопки, как показано ниже.

Щелкните на кнопке Параметры страницы. Ваша программа откроет диалоговое окно Page Setup, показанное ниже.

Page Setup содержит множество полезных опций, включая возможность изменить размер и источник страниц, ориентацию печати: Portrait (Портретная) или Landscape (Альбомная); и поля страниц: Left (левое), Right (правое), Top (верхнее) и Bottom (нижнее).

Щелкните на кнопке Предварительный просмотр. Ваша программа откроет диалоговое окно Предварительный просмотр, показанное на следующей иллюстрации.

Диалоговое окно Предварительный просмотр имеет несколько знакомых кнопок и функций предварительного просмотра, особенно если вы использовали команду Предварительный просмотр из Microsoft Word или Microsoft Excel. Элементы управления Zoom (Масштаб), One Page (Одна страница), Two Pages (Две страницы), Three Pages (Три страницы), Four Pages (Четыре страницы), Six Pages (Шесть страниц) и Page Select (Выбор страницы) этого диалогового окна работают автоматически. Для их работы не требуется никакого кода.

Щелкните на кнопке One Page (Одна страница), а затем на стрелке вверх поля Page Select, чтобы увидеть страницы 2-4. Это окно Предварительный просмотр впечатляет - и вы встроили его в вашу программу, добавив всего несколько строк кода!