Использование условных структур

Проверка пользователей с помощью If ... Then

Запустите Visual Studio и создайте в папке c:\vbnet03sbs\Гл.6 новый проект Windows Application (Приложение Windows) на Visual Basic с именем My User Validation. Будет создан новый проект и в Windows Forms Designer (Конструктор Windows Forms) появится пустая форма.

С помощью элемента управления Button на закладке Windows Forms окна области элементов создайте кнопку в верхнем левом углу формы.

Установите свойство Text этой кнопки равным "Войти".

С помощью элемента управления PictureBox создайте на форме под кнопкой прямоугольную область вывода изображений. Ваша форма должна выглядеть примерно так.

Сделайте двойной щелчок мышью на кнопке Войти. В Редакторе кода появится процедура события Button1_Click.

Введите в этой процедуре события следующие операторы:

Dim UserName As String
UserName = InputBox("Введите ваше имя.")
If UserName = "Генри" Then
MsgBox("Добро пожаловать, Генри! Как поживаешь?")
PictureBox1.Image = System.Drawing.Image.FromFile _
("c:\vbnet03sbs\Гл.6\henry photo.jpg")
ElseIf UserName = "Феликс" Then
MsgBox("Добро пожаловать, Феликс! Сыграем?")
PictureBox1.Image = System.Drawing.Image.FromFile _
("c:\vbnet03sbs\Гл.6\felix photo.jpg")
Else
MsgBox("Извините, я вас не знаю.")
End		'выход из программы
End If

Пробел и символ продолжения строки (_), использованные после свойств PictureBox1.Image, разбивают слишком длинные операторы программы на четыре строки. Вы можете ввести каждый из этих длинных операторов в одну строку; при этом Редактор кода будет прокручиваться вправо.

Совет. Строки программы в Редакторе кода и Visual Studio могут иметь в длину более 65 000 символов, но обычно проще всего работать со строками, длина которых не превышает 80 символов. Вы можете разбить длинные операторы программы на несколько строк с помощью пробела и символа продолжения строки (_), которые ставятся в конце всех строк выражения, за исключением последней. Однако нельзя использовать символ продолжения строки для разделения строковой константы, заключенной в кавычки.

Когда вы закончите, ваш экран должен выглядеть так.

Чтобы сохранить изменения, щелкните на кнопке Save All (Сохранить все) на стандартной панели инструментов.

Щелкните на кнопке Start (Начать) стандартной панели инструментов. Программа запустится на выполнение в среде разработки. На экране появится пустая форма с единственной кнопкой Войти в верхнем левом углу.

Щелкните на кнопке Войти. Функция InputBox в процедуре события Button1_Click отображает диалоговое окно, которое просит вас ввести свое имя.

Введите Генри, а затем щелкните на OK.

Примечание. Проверки условий в этой программе учитывают регистр букв, так что убедитесь, что вы ввели "Генри", а не "генри".

Структура выбора If...Then сравнивает в первом условном выражении имя, которое вы ввели, с именем "Генри". Выражение равно True, и оператор If...Then отображает с помощью функции MsgBox приветственное сообщение.

Щелкните в окне сообщения на OK. Окно сообщения закроется, а в области вывода изображений появится фото в формате JPEG.

Процедура, использованная для загрузки картинки, та же, что была показана в лекциях 3 и 4 этой книги - я использую метод System.Drawing.Image.FromFile, который является частью пространства имен (или библиотеки объектов) System.Drawing. Этот метод специально разработан для загрузки изображений из файлов.

Щелкните на кнопке Войти, введите Феликс, а затем щелкните на OK. На этот раз структура выбора выбирает случай ElseIf и пропускает пользователя Феликс в программу. На экране снова с помощью функции MsgBox отображается приветственное сообщение.

Щелкните в окне сообщения на OK. В объект вывода изображений загружается фотография в формате JPEG, ассоциированная с этим пользователем, как показано ниже.

Щелкните на кнопке Войти, введите Селли, а затем щелкните на OK. Исполняется блок Else структуры выбора, и в окне сообщения появляется следующее сообщение.

Чтобы закрыть окно сообщения, щелкните на OK. Окно сообщения закроется, и программа остановится. Ваш код не допустил неавторизованного пользователя к использованию программы. Полная программа User Validation доступна на диске в папке c:\vbnet03sbs\ Гл.6\user validation.

Использование логических операторов в условных выражениях

Если вы хотите включить в вашу структуру выбора более одного критерия выбора, то в структуре If...Then и ElseIf вы можете проверять более одного условного выражения. Эти дополнительные условия объединяются вместе с помощью одного или большего количества логических операторов, перечисленных в следующей таблице:

Следующая таблица содержит список нескольких примеров работы с логическими операторами. В этих выражениях предполагается, что строковая переменная Vehicle содержит значение "Велосипед", а целочисленная переменная Price содержит значение 200.

В следующем упражнении вы измените программу My User Validation так, чтобы она в процессе авторизации пользователя запрашивала у него пароль. Пользователь будет вводить пароль и вы должны изменить условия в структуре выбора If...Then и ElseIf так, чтобы для проверки введенного пароля они использовали оператор And.

Добавление защиты паролем с помощью оператора And

Dim UserName, Pass As String

Pass = InputBox("Введите пароль.")

If UserName = "Генри" And Pass = "цветок" Then

ElseIf UserName = "Феликс" And Pass = "листок" Then

"Закорачивание" с помощью AndAlso и OrElse

Visual Basic .NET предлагает два логических оператора, которые можно использовать в условных выражениях - AndAlso и OrElse. Эти операторы работают точно так же, как And и Or соответственно, но несколько по-другому вычисляются. Это отличие будет новым для тех программистов, которые уже имеют опыт работы с предыдущими версиями Visual Basic.

Рассмотрим оператор If, который содержит два условия, связанные оператором AndAlso. Чтобы выполнились операторы структуры If, необходимо, чтобы оба условия были равны True. Если первое условие равно False, то Visual Basic .NET немедленно перейдет к следующей строке или оператору Else, не проверяя второго условия. Такое частичное, или укороченное, вычисление оператора If имеет логический смысл - зачем Visual Basic должен продолжать проверять оператор If, если оба условия не могут быть равны True?

Оператор OrElse работает аналогичным образом. Рассмотрим оператор If, который содержит два условия, связанные с оператором OrElse. Чтобы выполнились операторы структуры If, необходимо, чтобы хотя бы одно из условий было равны True. Если первое условие равно True, то Visual Basic .NET немедленно перейдет к выполнению операторов в структуре If, не проверяя второго условия.

Вот пример такой короткой ситуации в Visual Basic .NET - это простая процедура, которая использует оператор If и оператор AndAlso для проверки двух условий и отображения сообщения "Внутри If" при условии, что оба условия равны True:

Dim Number As Integer = 0
If Number = 1 AndAlso MsgBox("Проверка второго условия") Then
MsgBox("Внутри If")
Else
MsgBox("Внутри Else")
End If

Функция MsgBox сама используется как вторая проверка условия, что несколько необычно, но странная запись полностью корректна и дает нам прекрасную возможность увидеть в деталях, как работает "закорачивание". Текст "Проверка второго условия" появляется в окне сообщения только тогда, когда переменная Number равна 0; в противном случае оператор AndAlso обходит выражение If, и вторая часть условия не вычисляется. Если вы попробуете запустить этот код, помните, что он предназначен только для демонстрации - вы не станете использовать MsgBox в такой записи потому, что на самом деле она ничего не проверяет. Но, изменяя значение переменной Number с 0 на 1 и обратно, вы можете представить себе, как работает оператор AndAlso и обход проверки условий.

Вот второй пример того, как работает "закорачивание" в Visual Basic .NET, когда два условия проверяются с помощью оператора AndAlso. На этот раз после оператора AndAlso используется более сложное условие ( 7 / HumanAge <= 1 ), которое пересчитывает возраст человека в число собачьих жизней:

Dim HumanAge As Integer
HumanAge = 7
' Один год для собаки - это семь лет для человека
If HumanAge <> 0 AndAlso 7 / HumanAge <= 1 Then
MsgBox("Вам как минимум один ""собачий""  год")
Else
MsgBox("Вам менее одного "собачьего" года ")
End If

Эта процедура пытается определить, равно ли значение в целой переменной HumanAge, по крайней мере, 7. Она является частью более сложной программы, которая определяет так называемые "собачий" возраст человека, поделив его текущий возраст на 7. (Если вы раньше не слышали о концепции "собачьего" возраста, то слушайте - следуя этой логике, человеку, которому 28 лет, исполнилось 4 "собачьих" года.) Этот код использует в операторе If два условия и может быть использован в различных условиях - я использовал его в процедуре события Click для объекта кнопки. Первое условие проверяет, не равно ли значение переменной HumanAge нулю - я предположил, что пользователь - достаточно здравомыслящий человек, и введет в HumanAge положительный возраст, так как отрицательное значение приведет к неверным результатам. Второе условие проверяет, равен ли возраст человека, по крайней мере, семи. Если оба условия имеют значение True, то в окне сообщения отображается сообщение "Вам как минимум один "собачий" год". Если человеку меньше семи лет, то отображается сообщение "Вам менее одного "собачьего" года". Теперь представьте, что я изменил значение переменной HumanAge с 7 на 0. Что произойдет? Компилятор Visual Basic .NET определяет, что первое условие оператора If становится равным False, и это предотвращает вычисление второго условия, таким образом останавливая, или "закорачивая", оператор If и уберегая нас от ужасной ошибки "деление на ноль", которая возникла бы, если бы мы разделили 7 на 0 (Новое значение переменной HumanAge ). Хотя у нас и есть возможность воспользоваться преимуществами "закорачивания" в Visual Studio .NET, у нас нет такой же возможности в Visual Basic 6. Установка переменной HumanAge на 0 при использовании Visual Basic 6 приведет к возникновению ошибки времени исполнения и обрушению программы, так как вычисляется весь оператор If, а деление на 0 в Visual Basic 6 запрещено.

В качестве резюме можно сказать, что операторы AndAlso и OrElse в Visual Basic .NET дают программистам на Visual Basic несколько новых возможностей, включая предотвращение потенциальных ошибок времени исполнения и других неожиданных результатов. Стало также возможно увеличить производительность, поместив условия, которые требуют для своего вычисления много времени, в конце условного оператора. Visual Basic .NET не будет выполнять эти дорогостоящие вычисления условий до тех пор, пока это станет необходимо. Однако вы должны тщательно продумать все возможные условия, с которыми могут столкнуться операторы If при изменении состояний переменных во время выполнении программы.

Структуры выбора Select Case

Для управления исполнением операторов программы часто применяется структура выбора Select Case. В лекциях 3 и 5 этой книги вы уже использовали структуры Select Case, когда писали процедуры событий для обработки выбора элементов списков и раскрывающихся списков. Структура Select Case аналогична структуре If...Then...ElseIf, но она более эффективна, когда разветвление зависит от одной ключевой переменной. При использовании Select Case ваш код будет удобнее читать.

Синтаксис структуры Select Case следующий.

Select Case переменная
Case значение1
операторы программы, исполняемые, если переменная содержит значение 1
Case значение 2
операторы программы, исполняемые, если переменная содержит значение 2
Case значение 3
операторы программы, исполняемые, если переменная содержит значение 3
...
Case Else
операторы программы, исполняемые, если совпадения не найдено"
End Select

Структура Select Case начинается с ключевых слов Select Case и заканчивается ключевыми словами End Select. В качестве переменной вы можете использовать переменную, свойство или другое выражение, которое будет ключевым значением, т.е. проверяемым условием этой структуры. Значения значение 1, значение 2 и значение 3 можно заменить числами, строками или другими значениями, связанными с проверяемым условием. Если одно из этих значений совпадает со значением variable, то выполняются операторы, расположенные за соответствующим ему разделом Case. Затем Visual Basic переходит к строке, расположенной после оператора End Select и начинает с него дальнейшее исполнение кода. Вы можете включить в структуру Select Case любое количество выражений Case, а в каждое из этих выражений Case несколько значений. Если вы перечисляете несколько значений, разделяйте их запятыми.

В следующем примере показано, как структура Select Case используется в программе для печати нужного сообщения о возрасте человека. Если переменная Age содержит значение 18, то свойству Text объекта метки присваивается строка "Теперь вы можете участвовать в выборах!".

Dim Age As Integer
Age = 18

Select Case Age
Case 16
Label1.Text = "Теперь вы можете водить машину!"
Case 18
Label1.Text = "Теперь вы можете участвовать в выборах!"
Case 21
Label1.Text = "Теперь вы можете пить вино."
Case 65
Label1.Text = "Теперь вы можете уволиться и жить в свое удовольствие!"
End Select

Структура Select Case поддерживает также оператор Case Else, который можно использовать для отображения сообщений, если со значением переменной не совпадает ни одно из предшествующих значений. Вот как Case Else будет работать в следующем примере. Обратите внимание, что я изменил значение Age на 25, чтобы активизировать вариант Case Else.

Dim Age As Integer
Age = 25

Select Case Age
Case 16
Label1.Text = "Теперь вы можете водить машину!"
Case 18
Label1.Text = "Теперь вы можете участвовать в выборах!"
Case 21
Label1.Text = "Теперь вы можете пить вино."
Case 65
Label1.Text = "Теперь вы можете уволиться и жить в свое удовольствие!"
Case Else
Label1.Text = "Вы в полном расцвете сил!"
End Select

Использование операторов сравнения вместе со структурой Select Case

Операторы сравнения позволяют включить в структуру Select Case диапазон значений. Для этого служат такие операторы сравнения Visual Basic, как =, <>, >, <, >= и <=. Чтобы использовать операторы сравнения, вы должны включить в выражение ключевое слово Is или ключевое слово To, определяющие производимое сравнение. Ключевое слово Is говорит компилятору о том, что требуется сравнить переменную с выражением, указанным после ключевого слова Is. Ключевое слово To определяет диапазон значений. Следующая структура использует Is, To и несколько операторов сравнения для того, чтобы проверить значение переменной Age и отобразить одно из пяти сообщений:

Select Case Age
Case Is < 13
Label1.Text = "Радуйся своему детству!"
Case 13 To 19
Label1.Text = "Радуйся своей молодости!"
Case 21
Label1.Text = "Пей вино с друзьями."
Case Is > 100
Label1.Text = "Прекрасно выглядишь!"
Case Else
Label1.Text = "Вы в полном расцвете сил."
End Select

Если значение переменной Age меньше 13, отображается сообщение "Радуйся своему детству!" Для возраста от 13 до 19 лет отображается сообщение "Радуйся своей молодости!", и так далее.

Структура выбора Select Case обычно гораздо яснее, чем структура If...Then, и более эффективна, когда вы на основе значения переменной или свойства делаете три или более ветвей. Однако когда вы делаете два или менее сравнений, или когда вы работаете с несколькими различными значениями, то вы, скорее всего, будете использовать структуру выбора If...Then.

В следующем упражнении вы увидите, как можно использовать структуру Select Case для обработки ввода из поля списка. Используйте для получения ввода свойства ListBox1.Text и ListBox1.SelectedIndexChanged, а затем для отображения приветствия на одном из четырех языков структуру Select Case.

Использование структуры Select Case для обработки списка

В меню File (Файл) щелкните на New (Создать), а затем Project (Проект). Появится диалоговое окно New Project (Создать проект).

В папке c:\vbnet03sbs\Гл.6 создайте новый проект Windows Application (Приложение Windows) на Visual Basic с именем My Case Greeting. В Конструкторе Windows Forms появится пустая форма.

Щелкните на элементе управления Label на закладке Windows Forms окна области элементов, а затем нарисуйте в верхней части формы большую метку, которая будет отображать название программы.

Под большой меткой названия нарисуйте метку поменьше.

Щелкните в области элементов на элементе управления ListBox, а затем нарисуйте под двумя имеющимися метками поле списка.

Для отображения вывода программы нарисуйте под полем списка еще две небольшие метки.

В области элементов выберите элемент управления Button, и нарисуйте в нижней части формы маленькую кнопку.

Щелкните на кнопке Properties (Свойства) стандартной панели инструментов, а затем установите свойства объектов в соответствии со следующей таблицей. Также установите свойства Name, так как понадобится следить сразу за многими объектами вашей формы.

Объект	Свойство	Установка
Form1	Text	Приветствие
Label1	Font	Times New Roman, Bold (Жирный), 12-point (12 пунктов)
	Name	lblTitle
	Text	"Интернациональная программа приветствий"
Label2	Name	lblTextBoxLabel
	Text	"Выберите страну"
Label3	Font	10 пунктов
	Name	lblCountry
	Text	пустой (empty)
Label4	BorderStyle	Fixed3D
	ForeColor	Red (Красный)
	Name	lblGreeting
	Text	пустой (empty)
ListBox1	Name	lstCountryBox
Button1	Name	btnQuit
	Text	"Выход"

Когда вы закончите установку свойств, ваша форма должна выглядеть примерно так.

Теперь нужно ввести код программы для инициализации списка.

Сделайте двойной щелчок мышью на форме. В Редакторе кода появится процедура события Form1_Load.

Для инициализации списка введите следующий код программы:

lstCountryBox.Items.Add("Англия")
lstCountryBox.Items.Add("Германия")
lstCountryBox.Items.Add("Мексика")
lstCountryBox.Items.Add("Италия")
lstCountryBox.Items.Add("Россия")

Для добавления элементов в список формы эти строки используют метод Add объекта список.

Чтобы переключиться обратно в Конструктор Windows Forms, щелкните на закладке Form1.vb [Design] в верхней части Редактора кода, а затем сделайте двойной щелчок мышью на объекте списка в вашей форме, чтобы отредактировать его процедуру события. В Редакторе кода появится процедура события lstCountryBox_SelectedIndexChanged.

Для обработки выбора, сделанного пользователем в списке, введите следующие строки:

lblCountry.Text = lstCountryBox.Text
Select Case lstCountryBox.SelectedIndex
Case 0
lblGreeting.Text = "Hello, programmer"
Case 1
lblGreeting.Text = "Hallo, programmierer"
Case 2
lblGreeting.Text = "Hola, programador"
Case 3
lblGreeting.Text = "Ciao, programmatore"
Case 4
lblGreeting.Text = "Здравствуй, программист"
End Select

Первая строка копирует имя выбранного элемента списка в свойство Text третьей метки формы (которую вы переименовали в lblCountry). Наиболее важным свойством, использованным в этом операторе, является lstCountryBox.Text, которое содержит текст элемента, выбранного в списке. Остальные операторы являются частью структуры выбора Select Case. Эта структура использует в качестве проверяемой переменной свойство lstCountryBox.SelectedIndex и сравнивает его с несколькими значениями. Свойство SelectedIndex всегда содержит номер выбранного элемента списка; самый первый элемент имеет номер 0, второй элемент - номер 1, следующий - 2, и т.д. С помощью SelectedIndex структура Select Case может быстро определить, что выбрал пользователь, и отобразить верное приветствие.

Снова откройте форму и сделайте двойной щелчок мышью на кнопке Выход ( btnQuit ). В Редакторе кода появится процедура события btnQuit_Click.

Введите в этой процедуре события End.

Чтобы сохранить изменения, щелкните на кнопке Save All (Сохранить все) на стандартной панели инструментов. Теперь запустите программу и посмотрите, как работает оператор Select Case. Готовый проект Case Greeting расположен в папке c:\vbnet03sbs\Гл.6\case greeting.

Чтобы запустить программу, щелкните на кнопке Start (Начать) стандартной панели инструментов.

Щелкните в списке Выберите страну на названии каждой из стран. Для каждой из перечисленных стран программа отображает приветствие. На иллюстрации показано приветствие для Италии.

Чтобы остановить программу, щелкните на кнопке Выход. Программа остановится, и вернется среда разработки.

В этой лекции вы закончили работать со структурами выбора If...Then и Select Case. Однако далее в этой книге у вас будет еще несколько возможностей поработать с ними. If...Then и Select Case - это два из наиболее важных и ключевых механизмов Visual Basic, и вы обнаружите, что будете использовать их почти в каждой программе.

Следующий шаг: обнаружение событий мыши

В начале лекции мы обсудили несколько событий, на которые могут реагировать программы, написанные на Visual Basic .NET, и узнали, как управлять различными типами событий с помощью структур выбора If и Select Case. В этом разделе вы добавите в программу Case Greeting обработчик события, который обнаруживает, когда указатель мыши на некоторое время "зависает" над полем списка с названиями стран. Вы напишите специальную процедуру - обработчик события - создав процедуру события поля списка для события MouseHover - одного из нескольких действий, связанных с мышью, следить за которыми и обрабатывать которые может Visual Basic .NET. Если пользователь некоторое время будет удерживать мышь над списком стран, но не будет делать выбора из-за того, что не будет знать, как это сделать, или из-за того, что будет занят чем-то другим, эта процедура события будет выводить сообщение "Пожалуйста, выберите страну".

Добавление обработчика события мыши

Откройте Редактор кода, если он еще не открыт.

В верхней части Редактора кода щелкните мышью на стрелке раскрывающегося списка Class Name (Имя класса), а затем на объекте lstCountryBox. (Используйте функцию ToolTip, которая поможет вам узнать элементы Visual Studio.)

Щелкните на стрелке раскрывающегося списка Method Name (Имя метода), а затем на событии MouseHover. Visual Basic откроет в Редакторе кода процедуру события lstCountryBox_MouseHover, как показано ниже.

Каждый объект формы имеет одну процедуру события, которая автоматически открывается при двойном щелчке мышью на этом объекте формы. Остальные процедуры событий необходимо открывать с помощью списка Method Name. Когда вы создаете процедуру события для работы с одним из событий объекта, она называется обработчиком события.

Введите в этой процедуре события lstCountryBox_MouseHover следующие операторы программы:

If lstCountryBox.SelectedIndex < 0 Or _
lstCountryBox.SelectedIndex > 4 Then
lblGreeting.Text = "Пожалуйста, выберите страну"
End If

Оператор If проверяет с помощью двух условных операторов и оператора Or свойство SelectedIndex объекта списка. Обработчик события предполагает, что если свойство SelectedIndex содержит значение в диапазоне от 0 до 4, то пользователю не требуется помощь в выборе названия страны. Но если свойство SelectedIndex содержит значение, выходящее за этот диапазон, то обработчик события выводит в метке приветствия в нижней части формы сообщение "Пожалуйста, выберите страну". Это сообщение появляется, когда пользователь задерживает мышь над полем списка, и исчезает, когда название страны выбрано.

Чтобы запустить программу, щелкните на кнопке Start (Начать).

Подведите указатель мыши к списку стран и немного подержите над ним. В метке появится сообщение "Пожалуйста выберите страну", напечатанное красными буквами, как показано ниже.

Щелкните в поле списка на названии страны. В метке появится приветствие на требуемом языке, а справочное сообщение исчезнет.

Чтобы выйти из программы, щелкните на кнопке Выход. Вы узнали, как обрабатывать в программе события мыши!

Краткая справка по лекции 6

If условие1 Then
Операторы, исполняемые, когда условие1 равно True
ElseIf условие2 Then
Операторы, исполняемые, когда условие2 равно True
Else
Операторы, исполняемые, когда ни одно из условий  не равно True.
End If

Select Case переменная
Case значение1
Операторы, исполняемые, если значение переменной совпадает со значением1
Case значение2
Операторы, исполняемые, если значение переменной совпадает со значением2
Case Else
Операторы, исполняемые, если со значением переменной  не совпадает ни один из вариантов
End Select