Управление ходом выполнения программ. Примеры типовых алгоритмов

Для управления ходом выполнения программ предоставляется ряд возможностей, ниже рассматриваются некоторые из них.

Условная инструкция If : Then : Else

Необходимость использования инструкции If : Then : Else возникает, если имеются альтернативные пути выполнения программы; при еe использовании проводится проверка условий и в зависимости от их истинности выполняются определeнные действия. Используется простой и полный синтаксис. Простой синтаксис:

If условие Then инструкция [Else инструкция]

- если условие, стоящее после If истинно ( True ), то выполняется инструкция, следующая за Then, если условие ложно ( False ), то выполняется инструкция, следующае за Else.

Полный синтаксис:

If условие 1 Then 
инструкция 1
.
[инструкция m]
[ElseIf условие 2 Then 
инструкция k] 
[Else
инструкция n]
End If

Во втором случае синтаксиса инструкция 1 : инструкция m,: записываются на новых строчках, присутствует инструкция End If. Наличие ElseIf позволяет анализировать дополнительные условия. Добавлением нескольких инструкций ElseIf можно анализировать дополнительное количество условий. Else используется для обработки противоположных ситуаций. Если нужно проверить некоторое условие при наличии другого условия, то используются вложенные инструкции, пример:

If условие 1 Then
If условие 2 Then 
инструкция 1
.
Else
инструкция m
End If
Else
инструкция n
End If

Для демонстрации различия синтаксиса рассмотрим пример нахождения максимального из 2-х чисел.

Dim max As Integer
If Val(txt1.Text) > Val(txt2.Text) Then max = Val(txt1.Text) Else max = Val(txt2.Text)
lblMax.Caption = max
или:
If Val(txt1.Text) > Val(txt2.Text) Then
max = Val(txt1.Text)
Else: max = Val(txt2.Text)
End If
lblMax.Caption = max

Цикл For : Next

Цикл For : Next предназначен для выполнения определeнного количества действий, когда количество действий известно заранее; синтаксис:

For начальное_значение переменной-счeтчик 
 To конечное_значение переменной-счeтчик [Step величина шага]
инструкции

Next [переменная-cчeтчик]

Сначала инициализируется начальное значение переменной-счeтчик, при каждом выполнении цикла еe значение увеличивается на величину шага, или на 1, если шаг не указан.

Практическая работа 9. Цикл For : Next

9а. Цикл For : Next, формирование массива, вычисление суммы элементов массива, вывод текстовые поля, поля списка и Label1.

Создать требуемые объекты, см. код процедуры Command1_Click(), данный ниже, очистить свойство Text текстового поля, а его свойству Multiline присвоить значение Тrue, тогда в процессе выполнения будет проводиться перенос строк в текстовое поле. Ввести код:

Private Sub Command1_Click()
Dim mass(15) As Integer, i As Integer
Rem переменная для хранения суммы элемeнтов массива
Dim summ As Integer 
For i = 0 To 14
mass(i) = i
' вывод элементов массива в поле списка
lst1.List(i) = mass(i) 
' вывод значений i в поле TextBox
txt1.Text = txt1.Text  " "  i 
Next i
summ = 0
For i = 0 To 14
' суммирование элементов маcсива
summ = summ + mass(i) 
Next i
lbl1.Caption = summ ' вывод суммы элементов 
End Sub

стартовать проект, сделать щелчок на командной кнопке.

9b. Цикл For : Next, формирование массива случайных чисел в заданном диапазоне, вычисление суммы элементов массива, вывод в поле списка и Label1.

Используется функция RND, возвращающая псевдослучайное число в диапазоне 0 - 1. Выражение вида: Int(КонецДиапазона - НачалоДиапазона + 1) * RND() + НачалоДиапазона) позволяет получить случайное целое число в заданном диапазоне. Функция Int возвращает целую часть числа.

Создать требуемые объекты, см. код, данный ниже и ввести код:

Private Sub Command1_Click()
Dim mass(15) As Integer, I As Integer, A As Integer, В As Integer
Dim Summ As Integer
A = -5: B = 5: Summ = 0
For I = 0 To 14
mass(I) = Int(Rnd * (B - A + 1) + A)
lst1.List(I) = mass(I)
Summ = Summ + mass(I)
Next I
lbl1.Caption = Summ
End Sub

стартовать проект, сделать щелчок на командной кнопке.

9c. Создание массива объектов, использование вложенного цикла For : Next для формирования двумерного массива, вывод элементов двумерного массива в массив поля списка и суммы элементов массива в элемент управления Label1.

Создать на форме элемент управления CommandButton, создать массив полей списка, для этого:

ввести код:

Private Sub Command1_Click()
Dim mass(15, 3) As Single, i As Integer, j As Integer 
Dim A As Integer
Dim B As Integer, Summ As Single 
A = -5: B = 5: Summ = 0
For j = 0 To 14
For i = 0 To 2
mass(j, i) = Rnd * (B - A) + A
' вывод элементов в поля массива списка
List1(i).List(j) = mass(j, i) 
' суммирование элементов двумерного массива
Summ = Summ + mass(j, i) 
Next i, j
Label1.Caption = Summ ' вывод суммы элементов массива
End Sub

стартовать проект, сделать щелчок на командной кнопке.

Повтор набора инструкций - Do : Loop

Цикл Do : Loop используется, если точное количество повторений действий заранее неизвестно или нужно дождаться выполнения некоторого условия. Цикл Do : Loop может выполняться бесконечно:

Do
повторяющееся действие
Loop

Различают 2 варианта цикла Do : Loop с завершением:

Do While условие
инструкции
Loop

Do Until условие
инструкции
Loop

Практическая работа 10. Циклы Do : Loop

Создать массивы, вычислить сумму их элементов.

10а. Do While : , Do Until

Private Sub Command1_Click()
Dim sum As Integer, mas(5) As Integer, к As Integer
mas(0) = 5: mas(1) = 6: mas(2) = 7: mas(3) = 6: mas(4) = 7
к = 0: sum = 0
' здесь цикл повторяется до тех пор, пока значение
' переменной остается < 5 
Do While к < 5 
sum = sum + mas(к)
к = к + 1
Loop
lbl1.Caption = sum
End Sub

Private Sub Command2_Click()
Dim sum As Integer, mas(5) As Integer, к As Integer
mas(0) = 5: mas(1) = 6: mas(2) = 7: mas(3) = 6: mas(4) = 7
sum = 0: к = 0
Do Until к = 5 
sum = sum + mas(к)
к = к + 1
Loop
lbl2.Caption = sum
End Sub

Цикл Do : Loop часто применяется при считывании записей из файла:

Do While Not EOF #номер файла
EOF (End of File) - признак конца файла.

Циклы Do :Loop могут управляться в конце. В примерах, данных ниже расположение условий в начале/конце циклов равноценно.

10b. Цикл Do : Loop; расположение условий в начале, конце

Создать необходимые объекты, очистить свойства Caption элементов управления Label, ввести код, cтартовать проект, выполнить оба цикла.

Private Sub Command1_Click()
Dim i As Integer
i = 0
Do While i < 7
lbl1.Caption = lbl1.Caption  " "  i
i = i + 1
Loop
End Sub

Private Sub Command2_Click()
Dim i As Integer
i = 0
Do
lbl2.Caption = lbl2.Caption  " "  i
i = i+ 1
Loop While i < 7
End Sub

Условная инструкция Select Case: выбор ветви из набора условий

Использование блока Select Case позволяет принять решение при наличии нескольких условий; синтаксис:

Select Case переменная_выбора
Case 1 значение 1
инструкция 1
Case 2 значение 2
инструкция 2
.
' Case Else выполняется, если не выполнено ни одно из
' предыдущих условий 
Case Else 
инструкция k
End Select

Синтаксис Select Case разрешает использование условий < > =, при этом используется ключевое слово Is, пример:

Select Case people
Case Is < 100000
инструкция 1
Case Is < 500000
инструкция 2
End Select

В качестве значения для Case можно указывать не одно значение, а несколько через запятую. Пример использования:

Dim A As Single
A = Val(Text1.Text)
Select Case A
Case Is < 0: lbl1.Caption = "<0"
Case Is = 0: lbl1.Caption = "0"
Case Else: lbl1.Caption = ">0"
End Select

Безусловный переход

Инструкция безусловного перехода - это GoTo. Безусловный переход выполняется без анализа условий. Часто используется совместно с инструкцией On Error в обработчиках ошибок, см. ниже, праkтическая работа 50.

Вызов

Вызов Call в процедуре временно передаeт управление другой процедуре, после завершения которой управление снова передаeтся той процедуре, из которой последовал вызов. Вызов процедуры может выглядеть так: Call имя_вызываемой_процедуры

при этом инструкция Call может отсутствовать. Часто требуется передавать процедуре значения параметров, необходимых для еe выполнения.

Примеры:

' процедура Sub Peter() вызывает процедуру Sub FrZeit(Zeit), 
' передавая ей значение 7 для еe аргумента; после 
' завершения процедуры Sub FrZeit(Zeit) управление '
' возвращается к Sub Peter(). Далее Sub Peter() вызывает 
' процедуру Sub Message(); после щелчка пользователя
' на кнопке окна, выводимого функцией MsgBox, управление
' возвращается к Sub Peter(), которая завершается.
Sub Peter()
FrZeit 7
Message
End Sub

Sub FrZeit(zeit)
For i = 1 To zeit
.
Next
End Sub

Sub Message()
MsgBox "Es ist zu frueh" ' слишком рано
End Sub

' два способа вызова процедуры с несколькими аргументами
Sub Paul()
KlPause 15, 25
Call KlPause(11, 30)
End Sub

Sub KlPause(zeit As Integer, Dauer As Integer)
If zeit >= 12 Then
Dauer = Dauer*2
End If
End Sub

Процедуры

Процедура есть последовательность инструкций, объединeнных для выполнения. Различают процедуры обработки событий и процедуры общего назначения: процедуры Sub, Function, Property, Event.

Для создания процедуры общего назначения нужно использовать область окна кода ( General ) ( Declarations ) $$\to$$ меню Инструменты $$\to$$ Добавить процедуру $$\to$$ в поле выведенного диалогового окна ввести имя процедуры $$\to$$ в поле Тип сделать щелчок на Sub $$\to$$ сделать выбор в поле Район $$\to$$ ОК $$\to$$ выводятся инструкции описания процедур.

Процедуры обработки событий (закрытые процедуры) являются процедурами типа Private; их можно вызвать только внутри формы. Процедуры являются общими (открытыми), если они могут быть вызваны процедурами другой формы/модуля; используется ключевое слово Public. Общая процедура должна содержаться в модуле.

Вызов процедуры из другой процедуры можно выполнить одним из следующих способов:

If kkKK > 70 Then
Proc1
End If

Call Proc1

Список аргументов процедуры, при необходимости с указанием типа, размещают в скобках в строке имени процедуры, при этом в процедурах обработки событий список аргументов определeн событием и не может быть изменeн пользователем.

При программировании необходимо контролировать передачу аргументов.

Передача аргументов может проводиться: по значению - ByVal ( в этом случае процедуре передаeтся копия этого значения) и по ссылке - ByRef (в этом случае вызванная процедура получает адрес памяти передаваемой переменной).

Инструкция в процедуре Sub/Function может передавать значения вызываемой процедуре, при этом могут использоваться именованные аргументы, которые можно перечислять в произвольном порядке. Именованный аргумент состоит из:

Private Sub Command1_Click()
Dim x1 As Variant
MsgBox Title:="отпуск", Prompt:="Едем в отпуск в Испанию" 
или
x1 = MsgBox(Title:="отпуск", _
Prompt:=" Едем в отпуск в Испанию", Buttons:=4)
End Sub

Процедура Function

Особенностью процедур Function является то, что результатом их работы является возвращаемое значение. При создании процедуры Function используется инструкция Function и в конце - инструкция End Function. Функция может получать аргументы, передаваемые ей вызывающей процедурой. Если аргументов нет, то скобки пусты. При использовании аргумента должен указываться соответствующий тип данных. За скобками указывается тип возвращаемого значения.

Вызов функции реализуется в соответствии с синтаксисом:

Возвращаемое_значение = Имя_функци(Аргумент_1, : Аргумент_к); пример:
х1 = Func1(20, 30)

Здесь вызывается функция Func1, в передаются значения 20, 30. Возвращаемое значение присваивается переменной х1.

Практическая работа 11. Создание функции

Создадим функцию вычисления факториала числа ( Factor ), используем тип вводимых данных - Integer, возвращаемых - Double, тогда максимальное возвращаемое значение ограничивается числом 1.80Е308. Примем факториал равным нулю, если значение аргумента превышает 170 (факториал 170 соответствует максимальному значению принятого типа данных). Последовательность действий:

Private Sub Command1_Click()
' проводится преобразование вводимых данных в 
' числовые значения, вычисляется факториал введeнного 
' числа, результат преобразуется в тип String и выводится 
' в поле txtOut
txtOut.Text = Str(Factor(Val(txtInp.Text))) 
End Sub

' указание типа данных аргумента и типа данных 
' возвращаемого фунцией значения
Public Function Factor(x As Integer) As Double
Dim i As Integer ' i - переменная-счeтчик
If x > 0 And x < 171 Then 
Factor = 1 
For i = 2 To x 
Factor = Factor * i 
Next i
Else
Factor = 1 
End If
End Function

Процедура Sub

Процедура Sub начинается инструкцией Sub и заканчивается инструкцией End Sub, между ними размещается код. Различают процедуры обработки событий и процедуры общего назначения. Процедуру обработки событий можно отличить по еe имени, содержащему имя события, например: Command1_Click (). Ниже приводится пример создания процедуры Sub.

Практическая работа 12. Создание процедуры Sub

Решается задача деления городов на группы в зависимости от соответствующей численности населения, которая задаeтся как набор случайных чисел. Рассматриваются 2 варианта:

Последовательность действий:

(General) (Declarations) 
Dim j As Integer

Private Sub Form_Load() ' задать численность населения
For j = 0 To 29
If lstName.List(j) >= "A" Then
lstNum.List(j) = Int(Rnd ^ 3 * 2000000 + 100000)
Else
lstNum.List(j) = -1
End If
Next j
End Sub

Private Sub Command1_Click()
Dim i1 As Integer, i2 As Integer, i3 As Integer
Dim i4 As Integer, i5 As Integer
j = 0: i1 = 0: i2 = 0: i3 = 0: i4 = 0: i5 = 0
Do Until Val (lstNum.List(j)) <= 0
Select Case Val(lstNum.List(j))
Case Is < 100000: i5 = i5 + 1
lst1.List(5) = "i5="  i5
Case Is < 500000
lstNameGr(0).List(i1) = lstName.List(j)
lstNumGr(0).List(i1) = lstNum.List(j): i1 = i1 + 1
lst1.List(1) = "i1="  i1
Case Is < 1000000
lstNameGr(1).List(i2) = lstName.List(j)
lstNumGr(1).List(i2) = lstNum.List(j): i2 = i2 + 1
lst1.List(2) = "i2="  i2
Case Is < 1500000
lstNameGr(2).List(i3) = lstName.List(j)
lstNumGr(2).List(i3) = lstNum.List(j): i3 = i3 + 1
lst1.List(3) = "i3="  i3
Case Is < 2000000
lstNameGr(3).List(i4) = lstName.List(j)
lstNumGr(3).List(i4) = lstNum.List(j): i4 = i4 + 1
lst1.List(4) = "i4="  i4
Case Is >= 2000000: i5 = i5 + 1
lst1.List(5) = "i5="  i5
End Select
j = j + 1
Loop
End Sub

Public Sub mList(i As Integer, k As Integer)
lstNameGr(k).List(i) = lstName.List(j)
lstNumGr(k).List(i) = lstNum.List(j): i = i + 1
lst1.List(k + 1) = "i = "  i
End Sub

стартовать проект, сделать щелчок на кнопке Call mList(i,k), наблюдать результат, рис. 2.3.

Private Sub Command2_Click()
Dim i1 As Integer, i2 As Integer, i3 As Integer, i4 As Integer
Dim i5 As Integer
j = 0: i1 = 0: i2 = 0: i3 = 0: i4 = 0: i5 = 0
Do Until lstNum.List(j) <= 0
Select Case Val(lstNum.List(j))
Case Is < 100000: i5 = i5 + 1: lst1.List(5) = "i5="  i5
Case Is < 500000: Call mList(i1, 0)
Case Is < 1000000: Call mList(i2, 1)
Case Is < 1500000: Call mList(i3, 2)
Case Is < 2000000: Call mList(i4, 3)
Case Is >= 2000000: i5 = i5 + 1: lst1.List(5) = "i5="  i5
End Select
j = j + 1
Loop
End Sub

(рис 2.3) Деление городов на группы в зависимости от соответствующей численности населения

Процедуры Property

Процедура Property состоит из последовательности инструкций, позволяющих создавать свойства объектов и работать с ними. Существует 2 типа процедур Property, табл. 2.1

Синтаксис процедур:

[Public | Private] [Static] Property {Get | Let} имя [(список аргументов)] [As тип]
инструкция 1
.
инструкция к
End Property

Здесь

Обычно процедуры свойств используются попарно.

Обязательные аргументы при описании процедур и синтаксис вызова процедур представлены в табл. 2.2 и табл. 2.3 соответственно.

Инструкции Property Let описывают текст программы, составляющей процедуру Property Let, которая присваивает значение свойству, аргументы могут передаваться ByRef и ByVal. Инструкции Property Get описывают текст программы, составляющей процедуру Property Get, считывающую значение свойства, аргументы могут передаваться ByRef и ByVal.

Упрощeнный синтаксис аргументов процедуры Property:

[ByVal | ByRef] имя_переменной [( )] [As тип]

Практическая работа 13. Процедуры Property Let, Property Get

Инструкции Property Let используются для описания процедуры Property Let, предназначеной для изменения значения свойства (здесь цвет волос). Инструкции Property Get используются для описания процедуры, считывающей значение свойства. Процедура возвращает текущий цвет. Последовательность действий:

(General) (Declarations)
Dim CurrentColor As Integer 
Const BLACK = 0, RED = 1, GREEN = 2

Private Sub Command1_Click()
Rem задать цвет волос с помощью процедуры Property Let 
Rem (синтаксис: свойство = аргумент)
hairColor = BLACK
lbl1.Caption = CurrentColor
End Sub

Rem процедура изменяет значение свойства цвет волос
Property Let hairColor(ByVal Color As Variant) 
Select Case Color
Case RED: CurrentColor = 1
Case GREEN: CurrentColor = 2
Case Else: CurrentColor = 0
End Select
End Property

Rem процедура возвращает текущий цвет волос 
Property Get hairColor() As Variant 
Select Case CurrentColor 
Case Is = 1: hairColor = 1
Case Is = 2: hairColor = 2
Case Is = 0: hairColor = 0
End Select
End Property

Private Sub Command2_Click()
Rem определить цвет волос с помощью процедуры Property
Rem Get (синтаксис: переменная = свойствo)
Dim Color As Variant
Color = hairColor
lbl2.Caption = Color
End Sub

Примеры типовых алгоритмов

Ниже приводятся примеры некоторых типовых алгоритмов.

Практическая работа 14. Краткие примеры: нахождение экстремума, создание признака конца списка, деление элементов массива на группы, сортировка и т.д.

14а. Нахождение максимального элемента (массива).

Private Sub Command1_Click()
Dim m(25) As Integer ' описание массива
' описание переменной для хранения максимального значения 
Dim max As Integer 
Dim j As Integer, i As Integer 'описание переменныx-счeтчик
' создание массива и вывод его элементов в поле списка
For i = 0 To 24 
m(i) = Int(Rnd * 40 + 1) 
lst1.List(i) = m(i) 
Next i
max = m(0) ' пусть m(0) будет максимальным элементом
For j = 1 To 24 ' поиск максимального элемента
' если текущий элемент массива больше текущего 
' максимального, то сделать его максимальным элементом
If m(j) > max Then max = m(j) 
Next j
lbl1.Caption = max ' вывод результата в поле lbl1
End Sub

14 в. Нахождение наибольшего из 2-х элементов, условная инструкция If ... Then ... Else

В университетах M и N число студентов x1 и x2 соответственно, стоимость обучения каждого за весь период обучения равна st1 и st2; обучение длится ja1 и ja2 лет соответственно. Определить где выше стоимость обучения за 1 год. Последовательность действий:

Private Sub Command1_Click()
Dim st1 As Single, st2 As Single, ja1 As Integer, ja2 As Integer
Dim x1 As Integer, x2 As Integer
x1 = 2000 ' ввод исходных данных
x2 = 3000: ja1 = 4: ja2 = 5: st1 = 250.5: st2 = 300.7
If x1 * st1 / ja1 > x2 * st2 / ja2 Then
txt1.Text = "Университет M:"  x1 * st1 / ja1 
Else
txt1.Text = "Университет N:"  x2 * st2 / ja2 
End If
End Sub

14с. Создание списка данных типа String, создание признака конца списка, вывод списка в массив

Задание: создать список названий футбольных клубов страны. Переписать список в массив football(j). Последовательность действий:

(General) (Declarations)
Dim football(20) As String ' описание массива названий клубов

Private Sub Form_Load()
Dim j As Integer, i As Integer, Аr As String 
' Аr - условное название клуба
For j = 0 To 14 ' формирование списка названий клубов
Ar = "C" ' часть условного названия клуба
' формирование условных названий клубов
For i = 0 To 2 
Ar = Ar  Int(Rnd * 10 + 1)
Next i
lst1.List(j) = Ar ' вывод названий в поле ListBox
Next j
' создание признака конца списка. После инструкции 
' Next значение переменной-счётчик увеличивается на 1
lst1.List(j) = "-1" 
End Sub

' переписывать список в массив football(20) до тех пор, пока не 
' появится признак конца списка
Private Sub Command1_Click() 
Dim j As Integer
j = 0
Do Until lst1.List(j) = "-1"
football(j) = lst1.List(j)
lst2.List(j) = football(j)
j = j + 1
Loop
lbl1.Caption = j ' определить, сколько элементов переписано
End Sub