Типы данных

Использование стека

Будем рассматривать последовательности открывающихся и закрывающихся круглых и квадратных скобок ( ) [ ]. Среди всех таких последовательностей выделим правильные - те, которые могут быть получены по таким правилам:

Пример. Последовательности (), $${[[}\,{]]}$$, $${[()[}\,{]()][}\,{]}$$ правильны, а последовательности ], )(, (], ([)] - нет.

6.1.1. Проверить правильность последовательности за время, не превосходящее константы, умноженной на ее длину. Предполагается, что члены последовательности закодированы числами:$$\begin{tabular}{rr} {(} 1 \\ {[} 2 \\ {)} -1 \\ {]} -2 \end{tabular}$$

Решение. Пусть $${a[1]}\ldots{a[n]}$$ - проверяемая последовательность. Разрешим хранить в стеке открывающиеся круглые и квадратные скобки (т. е. 1 и 2).

Вначале стек делаем пустым. Далее просматриваем члены последовательности слева направо. Встретив открывающуюся скобку (круглую или квадратную), помещаем ее в стек. Встретив закрывающуюся, проверяем, что вершина стека - парная ей скобка; если это не так, то можно утверждать, что последовательность неправильна, если скобка парная, то заберем ее (вершину) из стека. Последовательность правильна, если в конце стек оказывается пуст.

Сделать_пустым (s);
i := 0; Обнаружена_ошибка := false;
{прочитано i символов последовательности}
while (i < n) and not Обнаружена_ошибка do begin
| i := i + 1;
| if (a[i] = 1) or (a[i] = 2) then begin
| | Добавить (a[i], s);
| end else begin  {a[i] равно -1 или -2}
| | if Пуст (s) then begin
| | | Обнаружена_ошибка := true;
| | end else begin
| | | Взять (t, s);
| | | Обнаружена_ошибка := (t <> - a[i]);
| | end;
| end;
end;
Правильно := (not Обнаружена_ошибка) and Пуст (s);

Убедимся в правильности программы.

(1) Если последовательность построена по правилам, то программа даст ответ "да". Это легко доказать индукцией по построению правильной последовательности. Надо проверить для пустой, для последовательности AB в предположении, что для A и B уже проверено, и, наконец, для последовательностей [A] и (A) - в предположении, что для A уже проверено. Для пустой очевидно. Для AB действия программы происходят как для A и кончаются с пустым стеком; затем все происходит как для B. Для [A] сначала помещается в стек открывающая квадратная скобка и затем все идет как для A - с той разницей, что в глубине стека лежит лишняя скобка. По окончании A стек становится пустым - если не считать этой скобки - а затем и совсем пустым. Аналогично для (A).

(2) Покажем, что если программа завершает работу с ответом "да", то последовательность правильна. Рассуждаем индукцией по длине последовательности. Проследим за состоянием стека в процессе работы программы. Если он в некоторый промежуточный момент пуст, то последовательность разбивается на две части, для каждой из которых программа дает ответ "да"; остается воспользоваться предположением индукции и определением правильности. Пусть стек все время непуст. Это значит, что положенная в него на первом шаге скобка будет вынута лишь на последнем шаге. Тем самым, первый и последний символы последовательности - это парные скобки, и последовательность имеет вид (A) или [A], а работа программы (кроме первого и последнего шагов) отличается от ее работы на A лишь наличием лишней скобки на дне стека (раз ее не вынимают, она никак не влияет на работу программы). Снова ссылаемся на предположение индукции и определение правильности.

6.1.2. Как упростится программа, если известно, что в последовательности могут быть только круглые скобки?

Решение. В этом случае от стека остается лишь его длина, и мы фактически приходим к такому утверждению: последовательность круглых скобок правильна тогда и только тогда, когда в любом ее начальном отрезке число закрывающихся скобок не превосходит числа открывающихся, а для всей последовательности эти числа равны.

6.1.3. Реализовать с помощью одного массива два стека, суммарное количество элементов в которых ограничено длиной массива; все действия со стеками должны выполняться за время, ограниченное константой, не зависящей от длины стеков.

Решение. Стеки должны расти с концов массива навстречу друг другу: первый должен занимать места$${Содержание[1]}\ldots{Содержание[Длина1]},$$ а второй -$${Содержание[n]}\ldots{Содержание[n-Длина2+1]}$$ (вершины обоих стеков записаны последними).

6.1.4. Реализовать k стеков с элементами типа T, общее количество элементов в которых не превосходит n, с использованием массивов суммарной длины $$C ({n}+{k})$$, затрачивая на каждое действие со стеками (кроме начальных действий, делающих все стеки пустыми) время не более некоторой константы $$C$$. (Как говорят, общая длина массивов должна быть $$O({m}+{n})$$, a время на каждую операцию - $$O(1)$$.)

Решение. Применяемый метод называется "ссылочной реализацией". Он использует три массива:

Содержание: array [1..n] of T;
Следующий: array [1..n] of 0..n;
Вершина: array [1..k] of 0..n.

Удобно изображать массив Содержание как n ячеек с номерами $${1}\ldots{n}$$, каждая из которых содержит элемент типа T. Массив Следующий изобразим в виде стрелок, проведя стрелку из i в j, если Следующий[i]=j. (Если Следующий[i]=0, стрелок из i не проводим.) Содержимое s -го стека ( $${s}\in {1}\ldots{k}$$ ) хранится так: вершина равна Содержание[Вершина[s]], остальные элементы s -го стека можно найти, идя по стрелкам - до тех пор, пока они не кончатся. При этом$$\text{({s}-ый стек пуст)} \Leftrightarrow {Вершина[s]=0}.$$

Стрелочные траектории, выходящие из$${Вершина[1]},\ldots, {Вершина[k]}$$ (из тех, которые не равны 0 ) не должны пересекаться. Помимо них, нам понадобится еще одна стрелочная траектория, содержащая все неиспользуемые в данный момент ячейки. Ее начало мы будем хранить в переменной Свободная (равенство $${Свободная} = {0}$$ означает, что пустого места не осталось). Вот пример:

Стеки: 1-ый содержит p, t, q, a ( a - вершина); 2-ой содержит s, v ( v - вершина).

procedure Начать_работу; {Делает все стеки пустыми}
| var i: integer;
begin
| for i := 1 to k do begin
| | Вершина [i]:=0;
| end;
| for i := 1 to n-1 do begin
| | Следующий [i] := i+1;
| end;
| Следующий [n] := 0;
| Свободная:=1;
end;

function  Есть_место: boolean;
begin
| Есть_место := (Свободная <> 0);
end;

procedure Добавить (t: T; s: integer);
| {Добавить t к s-му стеку}
| var i: 1..n;
begin
| {Есть_место}
| i := Свободная;
| Свободная := Следующий [i];
| Следующий [i] := Вершина [s];
| Вершина [s] :=i;
| Содержание [i] := t;
end;

function Пуст (s: integer): boolean;
| {s-ый стек пуст}
begin
| Пуст := (Вершина [s] = 0);
end;

procedure Взять (var t: T; s: integer);
| {взять из s-го стека в t}
| var i: 1..n;
begin
| {not Пуст (s)}
| i := Вершина [s];
| t := Содержание [i];
| Вершина [s] := Следующий [i];
| Следующий [i] := Свободная;
| Свободная := i;
end;

function  Вершина_стека (s: integer): T;
| {вершина s-го стека}
begin
| Вершина_стека := Содержание[Вершина[s]];
end;

6.2. Очереди

Значениями типа "очередь элементов типа T ", как и для стеков, являются последовательности значений типа T. Разница состоит в том, что берутся элементы не с конца, а с начала (а добавляются по-прежнему в конец).

Операции с очередями:

При выполнении команды "Добавить" указанный элемент добавляется в конец очереди. Команда "Взять" выполнима, лишь если очередь непуста, и забирает из нее первый (положенный туда раньше всех) элемент, помещая его в t. Значением функции "Очередной" (определенной для непустой очереди) является первый элемент очереди.

Английские названия стеков - Last In First Out (последним вошел - первым вышел), а очередей - First In First Out (первым вошел - первым вышел). Сокращения: LIFO, FIFO.

Реализация очередей в массиве

6.2.1. Реализовать операции с очередью ограниченной длины так, чтобы количество действий для каждой операции было ограничено константой, не зависящей от длины очереди.

Решение. Будем хранить элементы очереди в соседних элементах массива. Тогда очередь будет прирастать справа и убывать слева. Поскольку при этом она может дойти до края, свернем массив в окружность.

Введем массив

Содержание: array [0..n-1] of T

и переменные

Первый: 0..n-1,
Длина : 0..n.

При этом элементами очереди будут$$\begin{multiline*} {Содержание [Первый]}, {Содержание [Первый+1]}, \ldots,\\ % {Содержание [Первый+Длина-1]}, \end{multiline*}$$ где сложение выполняется по модулю n. (Предупреждение. Если вместо этого ввести переменные Первый и Последний, значения которых - вычеты по модулю n, то пустая очередь может быть спутана с очередью из n элементов.)

Операции выполняются так.

Сделать пустой:

Длина := 0;
Первый := 0;

Добавить элемент:

{Длина < n}
Содержание [(Первый + Длина) mod n] := элемент;
Длина := Длина + 1;

Взять элемент:

{Длина > 0}
элемент := Содержание [Первый];
Первый := (Первый + 1) mod n;
Длина := Длина - 1;

Пуста:

Длина = 0

Очередной:

Содержание [Первый]

6.2.2. (Сообщил А.Г. Кушниренко) Придумать способ моделирования очереди с помощью двух стеков (и фиксированного числа переменных типа T ). При этом отработка n операций с очередью (начатых, когда очередь была пуста) должна требовать порядка n действий.

Решение. Инвариант: $$\textsl{стеки, составленные концами, образуют очередь}$$. (Перечисляя элементы одного стека вглубь и затем элементы второго наружу, мы перечисляем все элементы очереди от первого до последнего.) Ясно, что добавление сводится к добавлению к одному из стеков, а проверка пустоты - к проверке пустоты обоих стеков. Если мы хотим взять элемент, есть два случая. Если стек, где находится начало очереди, не пуст, то берем из него элемент. Если он пуст, то предварительно переписываем в него все элементы второго стека, меняя порядок (это происходит само собой при перекладывании из стека в стек) и сводим дело к первому случаю. Хотя число действий на этом шаге и не ограничено константой, но требование задачи выполнено, так как каждый элемент очереди может участвовать в этом процессе не более одного раза.

6.2.3. Деком называют структуру, сочетающую очередь и стек: класть и забирать элементы можно с обоих концов. Как реализовать дек ограниченного размера на базе массива так, чтобы каждая операция требовала ограниченного числа действий?

6.2.4. (Сообщил А.Г. Кушниренко.) Имеется дек элементов типа T и конечное число переменных типа T и целого типа. В начальном состоянии в деке некоторое число элементов. Составить программу, после исполнения которой в деке остались бы те же самые элементы, а их число было бы в одной из целых переменных.

Указание. (1) Элементы дека можно циклически переставлять, забирая с одного конца и помещая в другой. После этого, сделав столько же шагов в обратном направлении, можно вернуть все на место. (2) Как понять, прошли мы полный круг или не прошли? Если бы какой-то элемент заведомо отсутствовал в деке, то можно было бы его подсунуть и ждать вторичного появления. Но таких элементов нет. Вместо этого можно для данного n выполнить циклический сдвиг на n дважды, подсунув разные элементы, и посмотреть, появятся ли разные элементы через n шагов.

Применение очередей

6.2.5. Напечатать в порядке возрастания первые n натуральных чисел, в разложение которых на простые множители входят только числа 2, 3, 5.

Решение. Введем три очереди x2, x3, x5, в которых будем хранить элементы, которые в 2 ( 3, 5 ) раз больше напечатанных, но еще не напечатаны. Определим процедуру

procedure напечатать_и_добавить (t: integer);
begin
| writeln (t);
| Добавить (2*t, x2);
| Добавить (3*t, x3);
| Добавить (5*t, x5);
end;

Вот схема программы:

...сделать x2, x3, x5 пустыми
напечатать_и_добавить (1);
k := 1; { k - число напечатанных }
{инвариант: напечатано в порядке возрастания k минимальных
членов нужного множества; в очередях элементы, вдвое,
втрое и впятеро большие напечатанных, но не напечатанные,
расположенные в возрастающем порядке}
while k <> n do begin
| x := min (очередной(x2), очередной(x3), очередной(x5));
| напечатать_и_добавить (x);
| k := k+1;
| ...взять x из тех очередей, где он был очередным;
end;

Пусть инвариант выполняется. Рассмотрим наименьший из ненапечатанных элементов множества; пусть это x. Тогда он делится нацело на одно из чисел 2, 3, 5, и частное также принадлежит множеству. Значит, оно напечатано. Значит, x находится в одной из очередей и, следовательно, является в ней первым (меньшие напечатаны, а элементы очередей не напечатаны). Напечатав x, мы должны его изъять и добавить его кратные.

Длины очередей не превосходят числа напечатанных элементов.

Следующая задача связана с графами (к которым мы вернемся в лекции 9).

Пусть задано конечное множество, элементы которого называют вершина, а также некоторое множество упорядоченных пар вершин, называемых ребрами. В этом случае говорят, что задан ориентированный граф. Пару $$\langle p, q\rangle$$ называют ребром с началом p и концом q ; говорят также, что оно выходит из вершины p и входит в вершину q. Обычно вершины графа изображают точками, а ребра - стрелками, ведущими из начала в конец. (В соответствии с определением из данной вершины в данную ведет не более одного ребра ; возможны ребра, у которых начало совпадает с концом.)

6.2.6. Известно, что ориентированный граф связен, т.е. из любой вершины можно пройти в любую по ребрам. Кроме того, из каждой вершины выходит столько же ребер, сколько входит. Доказать, что существует замкнутый цикл, проходящий по каждому ребру ровно один раз. Составить алгоритм отыскания такого цикла.

Решение. Змеей будем называть непустую очередь из вершин, в которой любые две вершины соединены ребром графа (началом является та вершина, которая ближе к началу очереди). Стоящая в начале очереди вершина будет хвостом змеи, последняя - головой. На рисунке змея изобразится в виде цепи ребер графа, стрелки ведут от хвоста к голове. Добавление вершины в очередь соответствует росту змеи с головы, взятие вершины - отрезанию кончика хвоста.

Вначале змея состоит из единственной вершины. Далее мы следуем такому правилу:

while змея включает не все ребра do begin
| if из головы выходит не входящее в змею ребро then begin
| | удлинить змею этим ребром
| end else begin
| | {голова змеи в той же вершине, что и хвост}
| | отрезать конец хвоста и добавить его к голове
| | {"змея откусывает конец хвоста"}
| end;
end;

Докажем, что мы достигнем цели.

(1) Идя по змее от хвоста к голове, мы входим в каждую вершину столько же раз, сколько выходим. Так как в любую вершину входит столько же ребер, сколько выходит, то невозможность выйти означает, что голова змеи в той же точке, что и хвост.

(2) Змея не укорачивается, поэтому либо она охватит все ребра, либо, начиная с некоторого момента, будет иметь постоянную длину. Во втором случае змея будет бесконечно "скользить по себе". Это возможно, только если из всех вершин змеи не выходит неиспользованных ребер. В этом случае из связности следует, что змея проходит по всем ребрам.

Замечание по реализации на паскале. Вершинами графа будем считать числа $${1}\ldots{n}$$. Для каждой вершины i будем хранить число Out[i] выходящих из нее ребер, а также номера Num[i][1],..., Num[i][Out[i]] тех вершин, куда эти ребра ведут. В процессе построения змеи будем выбирать первое свободное ребро. Тогда достаточно хранить для каждой вершины число выходящих из нее использованных ребер - это будут ребра, идущие в начале списка.

6.2.7. Доказать, что для всякого n существует последовательность нулей и единиц длины $$2^n$$ со следующим свойством: если "свернуть ее в кольцо" и рассмотреть все фрагменты длины n (их число равно $$2^n$$ ), то мы получим все возможные последовательности нулей и единиц длины n. Построить алгоритм отыскания такой последовательности, требующий не более $$C^n$$ действий для некоторой константы C.

Указание. Рассмотрим граф, вершинами которого являются последовательности нулей и единиц длины $$n-1$$. Будем считать, что из вершины x ведет ребро в вершину y, если x может быть началом, а y - концом некоторой последовательности длины n. Тогда из каждой вершины входит и выходит два ребра. Цикл, проходящий по всем ребрам, и даст требуемую последовательность.

6.2.8. Реализовать k очередей с ограниченной суммарной длиной n, используя память $$O(n+k)$$ [= не более $$C(n+k)$$ для некоторой константы C ], причем каждая операция (кроме начальной, делающей все очереди пустыми) должна требовать ограниченного константой числа действий.

Решение. Действуем аналогично ссылочной реализации стеков: мы помним (для каждой очереди) первого, каждый участник очереди помнит следующего за ним (для последнего считается, что за ним стоит фиктивный элемент с номером 0 ). Кроме того, мы должны для каждой очереди знать последнего (если он есть) - иначе не удастся добавлять. Как и для стеков, отдельно есть цепь свободных ячеек. Заметим, что для пустой очереди информация о последнем элементе теряет смысл - но она и не используется при добавлении.

Содержание: array [1..n] of T;
Следующий: array [1..n] of 0..n;
Первый: array [1..k] of 0..n;
Последний: array [1..k] of 0..n;
Свободная : 0..n;

procedure Сделать_пустым;
| var i: integer;
begin
| for i := 1 to n-1 do begin
| | Следующий [i] := i + 1;
| end;
| Следующий [n] := 0;
| Свободная := 1;
| for i := 1 to k do begin
| | Первый [i]:=0;
| end;
end;

function Есть_место : boolean;
begin
| Есть_место := Свободная <> 0;
end;

function Пуста (номер_очереди: integer): boolean;
begin
| Пуста := Первый [номер_очереди] = 0;
end;

procedure Взять (var t: T; номер_очереди: integer);
| var перв: integer;
begin
| {not Пуста (номер_очереди)}
| перв := Первый [номер_очереди];
| t := Содержание [перв]
| Первый [номер_очереди] := Следующий [перв];
| Следующий [перв] := Свободная;
| Свободная := перв;
end;

procedure Добавить (t: T; номер_очереди: integer);
| var нов, посл: 1..n;
begin
| {Есть_место }
| нов := Свободная; Свободная := Следующий [Свободная];
| {из списка свободного места изъят номер нов}
| if Пуста (номер_очереди) then begin
| | Первый [номер_очереди] := нов;
| | Последний [номер_очереди] := нов;
| | Следующий [нов] := 0;
| | Содержание [нов] := t;
| end else begin
| | посл := Последний [номер_очереди];
| | {Следующий [посл] = 0 }
| | Следующий [посл] := нов;
| | Следующий [нов] := 0;
| | Содержание [нов] := t
| | Последний [номер_очереди] := нов;
| end;
end;

function Очередной (номер_очереди: integer): T;
begin
| Очередной := Содержание [Первый [номер_очереди]];
end;

6.2.9. Та же задача для деков вместо очередей.

Указание. Дек - структура симметричная, поэтому надо хранить ссылки в обе стороны (вперед и назад). При этом удобно к каждому деку добавить фиктивный элемент, замкнув его в кольцо, и точно такое же кольцо образовать из свободных позиций.

В следующей задаче дек используется для хранения вершин выпуклого многоугольника.

6.2.10. На плоскости задано n точек, пронумерованных слева направо (а при равных абсциссах - снизу вверх). Составить программу, которая строит многоугольник, являющийся их выпуклой оболочкой, за $$O(n)$$ [= не более чем $$Cn$$ ] действий.

Решение. Будем присоединять точки к выпуклой оболочке одна за другой. Легко показать, что последняя присоединенная точка будет одной из вершин выпуклой оболочки. Эту вершину мы будем называть выделенной. Очередная присоединяемая точка видна из выделенной (почему?). Дополним наш многоугольник, выпустив из выделенной вершины "иглу", ведущую в присоединяемую точку. Получится вырожденный многоугольник, и остается ликвидировать в нем " впуклости".

Будем хранить вершины многоугольника в деке в порядке обхода его периметра по часовой стрелке. При этом выделенная вершина является началом и концом (головой и хвостом) дека. Присоединение "иглы" теперь состоит в добавлении присоединяемой вершины в голову и в хвост дека. Устранение впуклостей несколько более сложно. Назовем подхвостом и подподхвостом элементы дека, стоящие за его хвостом. Устранение впуклости у хвоста делается так:

while по дороге из хвоста в подподхвост  мы поворачиваем
| у подхвоста влево ("впуклость") do begin
| выкинуть подхвост из дека
end

Таким же способом устраняется впуклость у головы дека.

Замечание. Действия с подхвостом и подподхвостом не входят в определение дека, однако сводятся к небольшому числу манипуляций с деком (надо забрать три элемента с хвоста, сделать что надо и вернуть).

Еще одно замечание. Есть два вырожденных случая: если мы вообще не поворачиваем у подхвоста (т.е. три соседние вершины лежат на одной прямой) и если мы поворачиваем на $$180^{\circ}$$ (так бывает, если наш многоугольник есть двуугольник). В первом случае подхвост стоит удалить (чтобы в выпуклой оболочке не было лишних вершин), а во втором случае - обязательно оставить.

6.3. Множества

Пусть T - некоторый тип. Существует много способов хранить (конечные) множества элементов типа T ; выбор между ними определяется типом T и набором требуемых операций.

Подмножества множества {1… n}

6.3.1. Используя память $$O(n)$$ [=пропорциональную n ], хранить подмножества множества $$\{1\ldots n\}$$.

Решение. Храним множество как array [1..n] of Boolean.

6.3.2. То же, но проверка пустоты должна выполняться за время C.

Решение. Храним дополнительно количество элементов.

6.3.3. То же при следующих ограничениях на число действий:

Решение. Дополнительно храним минимальный элемент множества.

6.3.4. То же при следующих ограничениях на число действий:

Решение. Храним минимальный, а для каждого - следующий и предыдущий по величине.

Множества целых чисел

В следующих задачах величина элементов множества не ограничена, но их количество не превосходит n.

6.3.5. Память $$Cn$$.

Решение. Множество представляем с помощью переменных

a:array [1..n] of integer, k: 0..n;

множество содержит k элементов $${a[1]},\ldots{a[k]}$$ ; все они различны. По существу мы храним элементы множества в стеке (без повторений). С тем же успехом можно было бы воспользоваться очередью вместо стека.

6.3.6. Память $$Cn$$.

Решение. См. решение предыдущей задачи с дополнительным условием $${a[1]}\ldots{a[k]}$$. При проверке принадлежности используем двоичный поиск.

В следующей задаче полезно комбинировать разные способы.

6.3.7. Используя описанные способы представления множеств, найти все вершины ориентированного графа, доступные из данной по ребрам. (Вершины считаем числами $${1}\ldots{n}$$.) Время не больше $$C\cdot{}$$ (общее число ребер, выходящих из доступных вершин).

Решение. (Другое решение смотри в лекции о рекурсии, задача 7.4.6.) Пусть num[i] - число ребер, выходящих из i, а $${out[i][1]},\ldots\ldots, {out[i][num[i]]}$$ - вершины, куда ведут ребра из вершины i.

procedure Доступные (i: integer);
|   {напечатать все вершины, доступные из i, включая i}
| var  X: подмножество 1..n;
|      P: подмножество 1..n;
|      q, v, w: 1..n;
|      k: integer;
begin
| ...сделать X, P пустыми;
| writeln (i);
| ...добавить i к X, P;
| {(1) P = множество напечатанных вершин; P содержит i;
|  (2) напечатаны только доступные из i вершины;
|  (3) X - подмножество P;
|  (4) все напечатанные вершины, из которых выходит
|      ребро в ненапечатанную вершину, принадлежат X}
| while X непусто do begin
| | ...взять какой-нибудь элемент X в v;
| | for k := 1 to num [v] do begin
| | | w := out [v][k];
| | | if w не принадлежит P then begin
| | | | writeln (w);
| | | | добавить w в P;
| | | | добавить w в X;
| | | end;
| | end;
| end;
end;

Свойство (1) не нарушается, так как печать происходит одновременно с добавлением в P. Свойство (2): раз v было в X, то v доступно, поэтому w доступно. Свойство (3) очевидно. Свойство (4): мы удалили из X элемент v, но все вершины, куда из v идут ребра, перед этим напечатаны.

6.3.8. Показать, что можно использовать и другой инвариант: P - напечатанные вершины; $$X \subset P$$ ; осталось напечатать вершины, доступные из X по ненапечатанным вершинам.

Оценка времени работы. Заметим, что изъятые из X элементы больше туда не добавляются, так как они в момент изъятия (и, следовательно, всегда позже) принадлежат P, а добавляются только элементы не из P. Поэтому тело цикла while для каждой доступной вершины выполняется не более, чем по разу, при этом тело цикла for выполняется столько раз, сколько из вершины выходит ребер.

Для X надо использовать представление со стеком или очередью (см. выше), для P - булевский массив.

6.3.9. Решить предыдущую задачу, если требуется, чтобы доступные вершины печатались в таком порядке: сначала заданная вершина, потом ее соседи, потом соседи соседей (еще не напечатанные) и т.д.

Указание. Так получится, если использовать очередь для хранения X в приведенном выше решении: докажите индукцией по k, что существует момент, в который напечатаны все вершины на расстоянии не больше k, а в очереди находятся все вершины, удаленные ровно на k.

Более сложные способы представления множеств будут разобраны в лекциях 13 (хеширование) и 14 (деревья).

6.4. Разные задачи

6.4.1. Реализовать структуру данных, которая имеет все те же операции, что массив длины n, а именно

а также операцию

(точнее, одного из минимальных элементов). Количество действий для всех операций должно быть не более $$\text {C log n}$$, не считая операции "начать работу" (которая требует не более Cn действий).

Решение. Используется прием, изложенный в разделе о сортировке деревом. Именно, надстроим над элементами массива как над листьями двоичное дерево, в каждой вершине которого храним минимум элементов соответствующего поддерева. Корректировка этой информации, а также прослеживание пути из корня к минимальному элементу требуют логарифмического числа действий.

6.4.2. Приоритетная очередь - это очередь, в которой важно не то, кто встал последним (порядок помещения в нее не играет роли), а кто главнее. Более точно, при помещении в очередь указывается приоритет помещаемого объекта (будем считать приоритеты целыми числами), а при взятии из очереди выбирается элемент с наибольшим приоритетом (или один из таких элементов). Реализовать приоритетную очередь так, чтобы помещение и взятие элемента требовали логарифмического числа действий (от размера очереди).

Решение. Следуя алгоритму сортировки деревом (в его окончательном варианте), будем размещать элементы очереди в массиве x[1..k], поддерживая такое свойство: x[i] старше (имеет больший приоритет) своих сыновей x[2i] и x[2i+1], если таковые существуют - и, следовательно, всякий элемент старше своих потомков. (Сведения о приоритетах также хранятся в массиве, так что мы имеем дело с массивом пар $$\langle$$ элемент, приоритет $$\rangle$$.) Удаление элемента с сохранением этого свойства описано в алгоритме сортировки. Надо еще уметь восстанавливать свойство после добавления элемента в конец. Это делается так:

t:= номер добавленного элемента
{инвариант: в дереве любой предок приоритетнее потомка,
    если этот потомок - не t}
while t - не корень и t старше своего отца do begin
| поменять t с его отцом
end;

Если очередь образуют граждане, стоящие в вершинах дерева, т.е. за каждым стоит двое, а перед каждым (кроме первого) - один, то смысл этого алгоритма ясен: встав в конец, приоритетный гражданин начинает пробираться к началу, вытесняя впереди стоящих - пока не встретит более приоритетного.

Замечание. Приоритетную очередь естественно использовать при моделировании протекающих во времени процессов. При этом элементы очереди - это ожидаемые события, а их приоритет определяется временем, когда они произойдут.