Управляющие операторы языка

program tabl_fun;
var 
   Xn, Xk : real;   { начальное и конечное значение аргумента }
   dX     : real;   { шаг изменения аргумента } 
   x, y   : real;   { текущие значения аргумента и функции }
   t      : real;   { параметр }
begin
    writeln('Введите Xn, Xk, dX, t');             { приглашение ко вводу данных }
    readln(Xn, Xk, dX, t);                       { ввод исходных данных – шаг 1 }
    writeln(' --------------------------- ');               { заголовок таблицы }
    writeln('|      X      |      Y      |');
    writeln(' --------------------------- ');
    x := Xn;                           { первое значение аргумента = Xn – шаг 2 }
    while x <= Xk do begin                            { заголовок цикла – шаг 7 }
        if x < 0 then y := t;             { вычисление значения функции - шаг 4 }
        if (x >= 0) and (x < 10) then y := t * x;                       { шаг 4 }
        if x >= 10  then y := 2 * t;                                    { шаг 4 }
        writeln('|', x:9:2,'    |', y:9:2,'    |');{ вывод строки табл. – шаг 5 }
        x := x + dX;          { переход к следующему значению аргумента - шаг 6 }
    end;
    writeln(' --------------------------- ');
end.

Параметром этого цикла, то есть переменной, управляющей его выполнением, является х. Для правильной работы цикла необходимо присвоить параметру начальное значение до входа в цикл (шаг 2). Блок модификации параметра цикла представлен оператором, выполняющимся на шаге 6. Для перехода к следующему значению аргумента текущее значение наращивается на величину шага и заносится в ту же переменную.

Цикл с постусловием repeat

Тело цикла с постусловием заключено между служебными словами repeat и until, поэтому заключать его в блок не требуется.

repeat
    тело цикла
until выражение

В отличие от цикла while, этот цикл будет выполняться, пока логическое выражение после слова until ложно. Как только результат выражения станет истинным, произойдет выход из цикла. Вычисление выражения выполняется в конце каждой итерации цикла.

Этот вид цикла применяется в тех случаях, когда тело цикла необходимо обязательно выполнить хотя бы один раз: например, если в цикле вводятся данные и выполняется их проверка.

Пример. Программа, вычисляющая квадратный корень вещественного аргумента X с заданной точностью eps по итерационной формуле:

где y ( n –1) — предыдущее приближение к корню (в начале вычислений выбирается произвольно), y ( n ) — последующее приближение. Процесс вычислений прекращается, когда приближения станут отличаться друг от друга по абсолютной величине менее, чем на )..

program square_root;
var X, eps,                            { аргумент и точность }
    Yp, Y : real;                      { предыдущее и последующее приближение }
begin
    repeat
        writeln('Введите аргумент и точность (больше нуля): ');
        readln(X, eps);
    until (X > 0) and (eps > 0);
    Y := 1;
    repeat
        Yp := Y;
        Y := (Yp + X / Yp) / 2;
    until abs(Y - Yp) < eps;
    writeln('Корень из ', X:6:3, ' с точноcтью ', eps:7:5,
             'равен ', Y:9:5);
end.

Цикл с параметром for

Этот оператор применяется, если требуется выполнить тело цикла заранее заданное количество раз. Параметр порядкового типа на каждом проходе цикла автоматически либо увеличивается, либо уменьшается на единицу.

for параметр := выражение_1 to выражение_2 do оператор
for параметр := выражение_2 downto выражение_1 do оператор

Выражения должны быть совместимы по присваиванию с переменной цикла (о правилах совместимости мы поговорим в конце третьей лекции), оператор — простым или составным. Циклы с параметром обычно применяются при работе с массивами.

Пример 1. Программа выводит на экран числа от 10 до 1 и подсчитывает их сумму:

var i, sum : integer;
begin
    sum := 0;
    for i := 10 downto 1 do begin 
        writeln(i); inc(sum, i) 
    end;
    writeln('Сумма чисел: ', sum);
end.

В этом цикле переменная i автоматически уменьшается на 1.

Пример 2. Программа выводит на экран символы от :

var ch : char;
begin
    for ch := 'a' to 'z' do write(ch:2)
end.

Здесь счетчик цикла ch символьного типа поочередно принимает значение каждого символа от 'a' до 'z'.

Выражения, определяющие начальное и конечное значения счетчика, вычисляются один раз до входа в цикл. Цикл for реализован в Паскале как цикл с предусловием.

После нормального завершения цикла значение счетчика не определено. Фактически оно равно первому значению, для которого выполняется условие выхода из цикла, но использовать это в программах не рекомендуется. Также не следует изменять значение счетчика внутри цикла вручную, например:

for i := 1 to 10 do begin inc(i,3); ... end;                           { плохо! }

Это может привести к зацикливанию программы.

Рекомендации по использованию циклов

Часто встречающимися ошибками при программировании циклов являются использование в теле цикла переменных, которым не были присвоены начальные значения, а также неверная запись условия продолжения цикла. Нужно помнить и о том, что в операторе while истинным должно являться условие повторения вычислений, а в операторе repeat — условие их окончания.

Чтобы избежать ошибок, рекомендуется:

Процедуры передачи управления

В Паскале есть несколько стандартных процедур, изменяющих последовательность выполнения операторов:

Кроме того, для передачи управления используется оператор перехода goto.

Рассмотрим пример применения процедуры передачи управления.

Пример. Программа вычисления значения функции sin x (синус) с помощью бесконечного ряда Тейлора с точностью $$\varepsilon$$ по формуле:

y = x - x3/3! + x5/5! - x7/7! +…

Этот ряд сходится при любых значениях аргумента. Точность достигается при |Rn| < ε, где Rn —остаточный член ряда, который для данного ряда можно заменить величиной Cn очередного члена ряда, прибавляемого к сумме.

Общий алгоритм прост: задать начальное значение суммы ряда, а затем многократно вычислять очередной член ряда и добавлять его к ранее найденной сумме, пока абсолютная величина очередного члена ряда не станет меньше заданной точности.

До выполнения программы предсказать, сколько членов ряда потребуется просуммировать, невозможно. В цикле такого рода есть опасность, что он никогда не завершится. Поэтому для надежности программы необходимо предусмотреть аварийный выход из цикла с печатью предупреждающего сообщения по достижении некоторого максимально допустимого количества итераций.

Прямое вычисление члена ряда по приведенной выше общей формуле, когда х возводится в степень, вычисляется факториал, а затем числитель делится на знаменатель, имеет два недостатка, которые делают этот способ непригодным: большая погрешность вычислений и их низкая эффективность. При вычислении очередного члена ряда предыдущий уже известен, поэтому следует воспользоваться рекуррентной формулой получения последующего члена ряда через предыдущий C_n+1 = C_n *T, где T — некоторый множитель. Подставив в эту формулу C_n и C_n+1 , получим выражение для вычисления Т:

program ch;
const MaxIter = 500;              { максимальное количество итераций }
var x, eps : double;              { аргумент и точность }
    c, y   : double;              { член ряда и его сумма }
    n      : integer;             { номер члена ряда }
    done   : boolean;             { признак достижения точности }
begin
    writeln('Введите аргумент и точность:');
    readln(x, eps);
    done := true;
    c := x; y := c;                { первый член ряда и нач. значение суммы }
    n := 0;
    while abs(c) > eps do begin
        c :=- c * sqr(x) /(2 * n + 2)/(2 * n + 3);     { очередной член ряда } 
        y := y + c;                         { добавление члена ряда к сумме }
        inc(n);
        if n > MaxIter then begin                { аварийный выход из цикла }
            writeln('Ряд расходится!');
            done := false; break
        end
    end;
    if done then
        writeln('Для аргумента ', x, ' значение функции: ', y, #13#10,
                'вычислено с точностью', eps, ' за ',  n, ' итераций');
    readln;
end.

Оператор перехода goto

Этот оператор имеет простой синтаксис: в точке программы, из которой требуется организовать переход, после слова goto через пробел записывается имя метки, например goto 1 или goto error. При программировании на Паскале необходимость в применении оператора перехода возникает, как правило, в двух случаях:

Во всех остальных случаях следует преобразовать алгоритм так, чтобы он мог быть записан с помощью базовых конструкций.