Игры

14.2. Игра "Поле чудес"

Игра "Поле чудес" заключается в следующем. Компьютер случайным образом выбирает слово из словаря и загадывает его пользователю. Пользователь должен угадать это слово. Он может ввести либо букву, либо сразу все слово. Если слово окажется неверным, то игра прекращается, пользователь проигрывает. В противном случае она продолжается до тех пор, пока слово не будет отгадано.

    open core, console

class facts
    word: (positive, string).
clauses
    word(1, "пароход").
    word(2, "паровоз").
    word(3, "самолет").
    word(4, "аэроплан").
    word(5, "корабль").
    word(6, "поезд").
    word(7, "дирижабль").
    word(8, "зонд").
    word(9, "аэростат").
    word(10, "стратостат").
    word(11, "ракета").
    word(12, "электровоз").

class facts
    number : positive := 0.
    currentWord : string := "".
    secretWord : string := "".
    attempt : positive := 0.

class predicates
    human_machine: ().
    replace : (string, string) -> string.
clauses
    human_machine():-
        No = math::random(number) + 1,
        word(No, Word),
        NormWord = string::toUpperCase(Word),
        currentWord := NormWord,
        Len = string::length(NormWord),
        secretWord := string::create(Len, "_"),
        std::repeat(),
            nl, write(string::replaceAll(secretWord, "_", " _ ")),
            write("\n\nНазовите слово или букву: "),
            String = string::toUpperCase(readLine()),
            attempt := attempt + 1,
            LenOfStr = string::length(String),
            if LenOfStr = 1, not(_ = string::search(secretWord, String))
            then if not(_ = string::search(currentWord, String)) then
                        write("\nНет такой буквы в этом слове.\n")
                    else secretWord := replace(secretWord, String) end if
            end if,
        ((string::isWhiteSpace(currentWord); String = NormWord),
        writef("\n\nСлово: %!\nКоличество попыток: %!", NormWord,
            attempt);
        LenOfStr > 1,
        writef("\n\nСлово: %\nВы назвали % и проиграли!",
            NormWord, String)),
        !.
    human_machine().

    replace(SecretWord, Letter) = replace(SecretWord1, Letter):-
        Pos = string::search(currentWord, Letter),
        !,
        currentWord := string::replacePart(currentWord, Pos, 1, " "),
        SecretWord1 = string::replacePart(SecretWord, Pos, 1, Letter).
    replace(SecretWord, _) = SecretWord.

    run():-
        write("Машина загадывает, человек угадывает!\n\n"),
        number := list::length([X || word(X, _)]),
        human_machine(),
        _ = readLine().

Предикат toUpperCase/2 переводит все символы строки в верхний регистр. Предикат search/2 возвращает позицию подстроки в строке. Предикат replaceAll/3 заменяет в строке все вхождения одной подстроки другой подстрокой. Предикат replacePart/4 заменяет подстрокой заданное количество элементов с указанной позиции.

14.3. Игра "Отгадай числа"

"Отгадай числа" — это игра для двух участников, которая состоит в следующем. Игроки загадывают по n целых чисел в пределах от 0 до 9 включительно, числа не повторяются. Цель игры — найти набор чисел, который загадал противник. Порядок чисел в наборе значения не имеет. Участник называет n чисел. Если среди них более половины совпадают с числами, загаданными противником, то право хода остается за ним. В противном случае ход переходит к другому игроку. Побеждает игрок, который первым правильно назовет весь набор чисел, загаданный противником. Данная игра является одним из вариантов игры "Быки и коровы" [9], в котором имеются только "коровы".

Приведенная ниже программа — это реализация игры человека с компьютером. Значение n запрашивается у пользователя. Компьютер загадывает набор n попарно-различных случайных чисел. Пользователь вводит числа через пробел. Первым ходит компьютер.

    open core, console, list

constants
    diglist : unsigned* = [1, 2, 3, 4, 5, 6, 7, 8, 9, 0].

class facts
    num: (unsigned, unsigned*, positive).
    digs : unsigned* := [].
    n : positive := 0.
class predicates
    readDigits: (positive) -> unsigned*.
    add: (unsigned, unsigned*, unsigned* [out], positive, 
        positive [out]).
    gen: (positive, unsigned) -> unsigned*.
    gen: (positive, unsigned, unsigned*) -> unsigned*.
    count: (unsigned*, unsigned*) -> positive.
    f: (positive) -> string.
clauses
    readDigits(N) = reverse(digs):-
        writef("Введите % % от 0 до 9 через пробел: > ", N, f(N)),
        digs := [], n := N,
        std::repeat(),
            try hasDomain(unsigned, X), X = read()
            catch _ do
                clearInput(), write("\nПовторите попытку: > "), fail
            end try,
            add(X, digs, L, n, N1),
            digs := L, n := N1,
        n = 0,
        clearInput(),
        !.
    readDigits(_) = [].

    f(N) = "чисел":-
        N > 4,
        !.
    f(_) = "числа".

    gen(N, R) = reverse(gen(N, R, [])).

    gen(N, R, L) = gen(N1, R, L1):-
        N > 0,
        !,
        add(math::random(R), L, L1, N, N1).
    gen(_, _, L) = L.

    add(X, L, [X | L], N, N - 1):-
        X < 10,
        not(isMember(X, L)),
        !.
    add(_, L, L, N, N).

    count(L, L1) = length(filter(L, {(X):- isMember(X, L1)})).

class predicates
    game: (positive).
    game: (positive, unsigned, unsigned*, unsigned*).
    game: (positive, unsigned, unsigned*, unsigned*, positive).
    move: (unsigned, positive) -> unsigned*.
    writeMessage: (unsigned, unsigned*, unsigned*).
    writeVariants: (unsigned).
    subset: (positive, unsigned*) -> unsigned* nondeterm.
    candidate: (positive) -> unsigned* nondeterm.
    isBad: (unsigned*) determ.
    toStr: (unsigned) -> string.
clauses
    subset(0, _) = []:- !.
    subset(N, [X | L]) = [X | subset(N - 1, L)].
    subset(N, [_ | L]) = subset(N, L).

    candidate(N) = L:-
        L = subset(N, diglist),
        not(isBad(L)).

    isBad(L):-
        num(0, L1, N),
        N <> count(L, L1),
        !.

    writeVariants(X):-
        num(X, L, N),
            write(L, " - ", N), nl,
        fail;
        succeed().

    game(N):-
        writef("Загадайте % различных чисел от 0 до 9\n", N),
        L = readDigits(N),
        write("\nНачинается игра\n"),
        game(N, 0, gen(N, length(diglist) + 0), L).

    game(N, X, L, L1):-
        L2 = move(X, N),
        K = count(L1, L2),
        write(L2, " - ", K), nl,
        assert(num(X, L2, K)),
        game(N, X, L, L1, K).

    game(N, X, L, L1, N):- !,
        writeMessage(X, L, L1).
    game(N, X, L, L1, K):-
        K > N div 2,
        !,
        game(N, X, L, L1).
    game(N, X, L, L1, _):-
        game(N, 1 - X, L1, L).

    move(0, N) = L:-
        write("\nХод компьютера\n"),
        L = candidate(N),
        !.
    move(_, N) = readDigits(N):-
        write("\nВаш ход\n"),
        writeVariants(1).

    toStr(0) = "компьютер":- !.
    toStr(_) = "человек".

    writeMessage(X, L, L1):-
        Player1 = toStr(X),
        Player2 = toStr(1 - X),
        writef("Выиграл %!\n% задумал %, % задумал %.\n",
            Player1, Player1, L, Player2, L1).

    run():-
        write("Количество угадываемых чисел: "),
        N = read(), clearInput(),
        game(N),
        _ = readLine().

Упражнения